# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on aspell-en

_pkgname='aspell'
_pkglang='hi'
_srclang="${_pkglang}"
_srcsv='6'
pkgname="${_pkgname}-i18n-dict-${_pkglang}"
# Example: _srcname='aspell6-en'
_srcname="${_pkgname}${_srcsv}-${_srclang}"
pkgver='0.02.0'
_srcver='0.02-0'
pkgrel='2'
pkgdesc='Hindi dictionary for Aspell'
arch=('i686' 'x86_64')
url='https://ftp.gnu.org/gnu/aspell/dict/0index.html'
license=('GPL-2')
groups=("${_pkgname}-i18n-dict" "${_pkgname}-dict"
        "g${_pkgname}-i18n-dict" "g${_pkgname}-dict"
        "gnu${_pkgname}-i18n-dict" "gnu${_pkgname}-dict"
        "gnu-${_pkgname}-i18n-dict" "gnu-${_pkgname}-dict")
depends=('aspell')
provides=("${_pkgname}-dict-${_pkglang}"
          "g${pkgname}" "g${_pkgname}-dict-${_pkglang}"
          "gnu${pkgname}" "gnu${_pkgname}-dict-${_pkglang}"
          "gnu-${pkgname}" "gnu-${_pkgname}-dict-${_pkglang}"
          "${_pkgname}-${_pkglang}")
conflicts=("${_pkgname}-${_pkglang}")
replaces=("${_pkgname}-${_pkglang}")
_source=("https://ftp.gnu.org/gnu/${_pkgname}/dict/${_srclang}/")
source=("${_source[0]}/${_srcname}-${_srcver}.tar.bz2"
        "${_source[0]}/${_srcname}-${_srcver}.tar.bz2.sig")
sha512sums=('298743e1e5988e26081d89ee6cdea3b2f3185ad81b3449b5fa3f644a2beaf488320f9468fbeeb7e6c7bcb3ae4b7116bd02f64c4e6f4c60f80c1a7c3b84946a93'
            'SKIP')
validpgpkeys=(# Aspell Dictionary Upload
              '78DEC3DB0AEA763951322BBF71C636695B147849')
unset _pkgname _pkglang _srclang _srcsv _source

build() {
  cd "${srcdir}/${_srcname}-${_srcver}"
  ./configure
  make 'V=1'
}

package() {
  cd "${srcdir}/${_srcname}-${_srcver}"
  make "DESTDIR=${pkgdir}" 'install'

  for i in 'COPYING' 'Copyright'; do
    install -Dm '644' "${i}" -t "${pkgdir}/usr/share/licenses/${pkgname}"
  done
  unset i _srcname _srcver
}