# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=antiword
pkgver=0.37
_debver=$pkgver
_debrel=16
pkgrel=3
pkgdesc="A free and libre reader for documents"
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('bash')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/a/antiword/antiword_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/a/antiword/antiword_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('f440e07ed7353ac147499e2ffe823c5ee7a03862c3bdb56182231644f8de7d728dbc430f46684a98cec17e09e831056bda336dac6be3f3ccb26ed5c60ee0d1da'
            '1242606ad49736e3909d6d24043ae4c93d089f21d0c7e69545bf1cb5ed3219d6a15b9887c709f2e4cbb546401f57bec514f1d680b885f0718b2d9efb6d3051dc')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$srcdir/$pkgname-$pkgver"

  sed -i "s|GLOBAL_INSTALL_DIR =.*|GLOBAL_INSTALL_DIR = /usr/bin|g" Makefile.Linux
  mv Makefile.Linux Makefile
  make OPT="$CFLAGS -DNDEBUG" LDFLAGS="$LDFLAGS"
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir" global_install

  # remove KDE-interface
  rm "$pkgdir/usr/bin/kantiword"

  install -Dm644 Docs/antiword.1 -t "$pkgdir/usr/share/man/man1"
  install -Dm644 Docs/COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
}