# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=acpica
pkgver=20200925
_debver=$pkgver
_debrel=8
pkgrel=3
pkgdesc="ACPI tools, including Intel ACPI Source Language compiler"
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('glibc')
makedepends=('flex' 'bison' 'quilt')
provides=('iasl')
conflicts=('iasl')
replaces=('iasl')
options=(!makeflags)
source=("${pkgname}-unix-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/a/acpica-unix/acpica-unix_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/a/acpica-unix/acpica-unix_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('a2adf9ea7a895e23c4dedc6268550b57476ebb4ec859f8fa3febfb4b3e01b267126ae72a669d7b63f2e384f2ae9ed0e6c84594e0ddc03063d33ffd02b109971e'
            '6efb3b814a1bcef9e9b0502af08cd0649f67fec1f3fdb1f99fb9c18a10c0f70298f2464ca1e6914b9731d16779982a3e6bf2d8fddf521722c7a0f4879f46c3b9')

prepare() {
  cd acpica-unix-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd acpica-unix-${pkgver}
  make
}

package() {
  cd acpica-unix-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 debian/copyright -t ${pkgdir}/usr/share/licenses/${pkgname}
}