# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=abiword
pkgver=3.0.6
_debver=$pkgver
_debrel=1
pkgrel=2
pkgdesc="Efficient, featureful, free and libre word processor with collaboration"
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('fribidi' 'wv' 'goffice' 'librsvg-legacy' 'enchant' 'desktop-file-utils' 'libical'
         'gtk-update-icon-cache' 'loudmouth' 'link-grammar' 'gtkmathview' 'aiksaurus' 'libxslt' 'libgsf' 'libots')
makedepends=('pkgconfig' 'boost' 'gobject-introspection' 'python-pygobject' 'autoconf-archive' 'quilt')
options=('!makeflags')
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/a/abiword/abiword_${pkgver}~dfsg.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/a/abiword/abiword_${_debver}~dfsg-${_debrel}.debian.tar.xz"
        "aiksaurus-plugin.m4"
        "command-plugin.m4"
        "python-override.patch"
        "boost-asio.patch"
        "liberation-fonts.patch")
sha512sums=('eb7769073ed50b420354bfb16bfa49a381b8d5737139917fe0466502d6b2713140dab4b6a846ce875da3e04b2ed9045f271986f71877607048bfd4de8ec374b3'
            '171fb6ae9034e622e2138fbb5cd7b4919aa6d224da220735419ad5ecc1bad373e7bc024f37ccf0dcf19fe46718896d269628f253a1bbe70fda37670e5b33ee3f'
            '6e28e62c837e62857d8b81a659440ca8f72f958e61c1d0cd59818f171fc7a175ded2423f07d742bdd4a6913c5571dfcec0e8d62b5a0ea8ec905cda55bf2601c3'
            '0c9df93e3ee7253493d6b4d08711a7dbcc37a5fcfd40780a83d81d7d29f39fa32b28eaf16c0025edf34cef1538e594548b8b2b64ba9b0c2165a60ebb9e29dc4d'
            '0d766ab53257cc9a0638bf137d1834e584ffe2f305115da4e91a6aaffa86fcd14c34b42667987250cf80f118679b5d6bc7ea92b08ea7be85007ef3498444ea1e'
            'ab6e19f66433549644d1c1aae9beb93de038240a0089d38235de78dc8932ade27a2f73383448d07a8683e4c5ef85b954584b16cfbba405e61c698a991f348579'
            'c89d0059a215a996e6df81284201012072fdbdc472c11e52bbc5208e35148a6d3f99b46a7e0e0a403c67c5b99540ec88a274f9e1dc82e2f87d6c1e417dc2a01c')

prepare() {
  mv "AbiWord-release-$pkgver" "$pkgname-$pkgver"
  cd "$pkgname-$pkgver"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/enchant2.patch

    quilt push -av
  fi

  # fix python override code to work with Python 3.x
  patch -Np1 -i ${srcdir}/python-override.patch

  # replace nonfree fonts support to liberation fonts
  patch -Np1 -i ${srcdir}/liberation-fonts.patch

  # install missing m4 file
  install -m644 ${srcdir}/aiksaurus-plugin.m4 plugins/aiksaurus/plugin.m4
  install -m644 ${srcdir}/command-plugin.m4 plugins/command/plugin.m4

  # generate m4 file for configure
  find plugins -name plugin.m4 | xargs cat > plugin-configure.m4

  ./autogen-common.sh
  libtoolize --force
  autoreconf -fi
}


build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr \
    --enable-shared \
    --disable-static \
    --enable-clipart \
    --enable-templates \
    --enable-plugins="aiksaurus bmp collab docbook \
                      epub freetranslation garble gdict gimp goffice grammar \
                      hrtext iscii kword loadbindings mathview mht \
                      opendocument openwriter openxml opml ots paint \
                      passepartout pdf presentation s5 urldict wml xslfo" \
    --enable-introspection
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}