# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=a2ps
pkgver=4.14
_debver=$pkgver
_debrel=8
pkgrel=2
pkgdesc="An Any to PostScript filter"
arch=('i686' 'x86_64')
url='https://www.gnu.org/software/a2ps/'
license=('GPL-3')
depends=('psutils' 'graphicsmagick-imagemagick-compat' 'perl')
makedepends=('gperf' 'help2man' 'quilt')
backup=('etc/a2ps/a2ps.cfg'
        'etc/a2ps/a2ps-site.cfg')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/a/a2ps/a2ps_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/a/a2ps/a2ps_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('fd6ac8ab47d789114c283e8ca508f7f56feabd1a189f4ac772cad9e6be7e3791e210892cfffd04ad1d39efe4b15386b2e61bf4cd56b70ed581c0554f36bfe06f'
            'a8107182cdc834a6601f72765af89abaa387eaca2f9e89c0f766404625a27361777221705c12724de6e6943a779d12dbf13f515890d19d84f3df309ee207584b')

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}

  LIBS+="-lm" ./configure \
    --prefix=/usr \
    --sysconfdir=/etc/a2ps \
    --includedir=/usr/include \
    --enable-shared \
    --enable-nls
  make
}

package() {
  cd ${pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}