# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=3proxy
pkgver=0.9.5
pkgrel=1
pkgdesc="A tiny, crossplatform, free and libre proxy server"
arch=('i686' 'x86_64')
url='https://www.3proxy.ru/'
license=('Modified-BSD')
install=$pkgname.install
depends=('glibc')
makedepends=('gcc' 'make')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/z3APA3A/3proxy/archive/${pkgver}.tar.gz"
        "remove-systemd.patch"
        "${pkgname}.initd"
        "${pkgname}.run")
sha512sums=('b668db6438da19ee2479228af744b9b3b9ff2c7e6d97aaf3b20737b165ab2baf656ac9ea92b6f1e169c428784c7d9e3e7eeb7c3effb1c0b77e5038319b6d2bcd'
            '3f238de59dcdc305f681118b81d1bfefc72ff1e265f3459b02922244a011ef3fea140d019866be2514785d6069c30e8a031654e6bf41413276a4de93e70ab51b'
            '58ddb5b0a1cfcac299a951c5dbfd09c6265572c9bfd2f5445970a2534b88bc0b19eb131c6195b79b3a018218da850312a3cb56bb5a3c733a66248d23423396a7'
            'c44d983f6a80582b912c068b2c300fdd3e4147f4a686a4c9b3dd8126d6fa7aeeaddd813ff83ba59a9aad21128f5a45d4ed190c8df2a87b9d487c378dcfaded14')

prepare() {
  cd $pkgname-$pkgver

  # arguments should be found in makepkg.conf, so let's remove them
  # install should not really perform anything but calling another targets
  sed --follow-symlinks -i.bak -e 's| -O2||g;s|CFLAGS = -g|CFLAGS =|;s|CC = gcc|CC ?= gcc|;s|LN = gcc|LN ?= gcc|' Makefile.Linux

  # additional fixes
  patch -Np1 -i ${srcdir}/remove-systemd.patch
}

build() {
  cd $pkgname-$pkgver

  make \
    prefix="/usr" \
    DESTDIR="$pkgdir" \
    ETCDIR="/etc/$pkgname" \
    INITDIR="/etc/init.d" \
    -f Makefile.Linux
}

package() {
  cd $pkgname-$pkgver

  make prefix="/usr" install \
    DESTDIR="${pkgdir}" \
    ETCDIR="${pkgdir}/etc/$pkgname" \
    INITDIR="${pkgdir}/etc/init.d" \
    RUNBASE="${pkgdir}/var/run" \
    LOGBASE="${pkgdir}/var/log" -f Makefile.Linux

  # correct the internal structures of files and folders being FHS-compliant
  # otherwise the makefile is leaving a complete mess when installed
  install -d "${pkgdir}"/usr/libexec/$pkgname
  mv "${pkgdir}"/usr/local/3proxy/libexec/*.so "${pkgdir}"/usr/libexec/$pkgname
  rm -rf "${pkgdir}/usr/local"
  ( cd "${pkgdir}"/usr/bin && mv proxy 3proxy-proxy ) || return 1
  rm -f \
    "${pkgdir}/etc/$pkgname/$pkgname.cfg" \
    "${pkgdir}/etc/$pkgname/conf" \
    "${pkgdir}/etc/init.d/$pkgname" \
    "${pkgdir}/var/log/$pkgname"
  mkdir -p "${pkgdir}/var/log/$pkgname"

  # add initial configuration-files and license
  install -Dm644 copying -t "${pkgdir}/usr/share/licenses/$pkgname"
  install -Dm644 cfg/3proxy.cfg.sample "${pkgdir}/etc/$pkgname/3proxy.cfg.sample"
  install -Dm644 cfg/counters.sample "${pkgdir}/etc/$pkgname/counters.sample"

  # install services
  install -Dm755 "${srcdir}"/$pkgname.initd "${pkgdir}"/etc/init.d/$pkgname
  install -Dm755 "${srcdir}/$pkgname.run" "${pkgdir}/etc/sv/$pkgname/run"
}