initial import

xorg-xcursor-themes/PKGBUILD

@@ -0,0 +1,37 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+# Based on xcursor-themes package
+
+pkgname=xorg-xcursor-themes
+pkgver=1.0.6
+pkgrel=2
+pkgdesc="X.Org Cursor themes"
+arch=(any)
+url="https://xorg.freedesktop.org/"
+license=('X11')
+makedepends=('pkg-config' 'xorg-xcursorgen' 'xenocara-util-macros')
+provides=('xcursor-themes')
+conflicts=('xcursor-themes')
+replaces=('xcursor-themes')
+source=(https://xorg.freedesktop.org/releases/individual/data/xcursor-themes-$pkgver.tar.bz2{,.sig})
+sha512sums=('2ad3586a5571a5ddc0001187362b54b839644916164834213af98e58698044aec4392dd6e1e42f1794fda85c8fedf259b09214a9636bd0e71a1629c710f198d3'
+            'SKIP')
+validpgpkeys=('4A193C06D35E7C670FA4EF0BA2FB9E081F2D130E') # Alan Coopersmith
+
+prepare() {
+  cd "xcursor-themes-$pkgver"
+  autoreconf -vfi
+}
+
+build() {
+  cd "xcursor-themes-$pkgver"
+  ./configure --prefix=/usr
+  make
+}
+
+package() {
+  cd "xcursor-themes-$pkgver"
+  make DESTDIR="$pkgdir" install
+
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}