initial import

whois/PKGBUILD

@@ -0,0 +1,36 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=whois
+pkgver=5.5.10
+pkgrel=2
+pkgdesc="Intelligent WHOIS client"
+arch=('i686' 'x86_64')
+url='https://github.com/rfc1036/whois'
+license=('GPL-2')
+depends=('libidn2')
+makedepends=('perl' 'gettext-tiny')
+backup=('etc/whois.conf')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/rfc1036/whois/archive/refs/tags/v$pkgver.tar.gz"
+        "gettext-tiny.patch")
+sha512sums=('5ee92c15146353e77dddcbeddb6e704e0c42d29b8c0ff899ecce80f8e39903e8c796daec7f3de3f197d382f88e7cd4abd470463ea6c13a01347d0cd15d99af28'
+            '2a5e5b2b133fd719c0265c6e81af36b87ef6b265173bb9e503b9dd378edbfa6d8c4b49b17e88dd4f900510ac993b7448f96d97d5b2e6b4f3f6a52eb067ff47bc')
+
+prepare() {
+  cd $pkgname-$pkgver
+  patch -Np1 -i "$srcdir/gettext-tiny.patch"
+}
+
+build() {
+  cd $pkgname-$pkgver
+  make \
+    CONFIG_FILE=/etc/whois.conf \
+    CFLAGS="$CFLAGS $CPPFLAGS" \
+    HAVE_ICONV=1
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make prefix=/usr BASEDIR="$pkgdir" install-whois
+  install -Dm644 whois.conf -t "$pkgdir/etc"
+  install -Dm644 COPYING -t $pkgdir/usr/share/licenses/$pkgname
+}