initial import

weechat/PKGBUILD

@@ -0,0 +1,55 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=weechat
+pkgver=4.6.3
+pkgrel=1
+pkgdesc="Fast, light and extensible IRC client with curses UI"
+arch=('i686' 'x86_64')
+url='https://www.weechat.org/'
+license=('GPL-3')
+depends=('gnutls' 'curl' 'libgcrypt')
+makedepends=('asciidoctor' 'cmake' 'aspell' 'guile' 'lua' 'perl' 'python'
+             'ruby' 'tcl' 'tk' 'gettext-tiny')
+optdepends=('aspell: spellchecker support'
+            'guile: support for guile scripts'
+            'lua: support for lua scripts'
+            'perl: support for perl scripts'
+            'python: support for python scripts'
+            'ruby: support for ruby scripts'
+            'tcl: support for tcl scripts'
+            'tk: support for tk')
+source=("https://www.weechat.org/files/src/${pkgname}-${pkgver}.tar.xz"
+        "fix-languages-cmake.patch")
+sha512sums=('60c3c7090e871fbdb0d4df4aed0f08faa8b669d5a442fb267942a58fd7151a73d1454bb54a54290b06cce71cc5dcbfb04b05efc85273c186a3168b09e39cd2bd'
+            '7f2580cd06eb4b5bd2c713e6715144d2feabe0c59f93c9c988fa1424746739904f4402fac470e8a7f49a030501aedebb4c9b82be7f93e5b744a048fce9ec88e9')
+
+# cmake does not correctly handle CPPFLAGS, so kludge it in anyway:
+# https://gitlab.kitware.com/cmake/cmake/-/issues/12928
+CFLAGS+=" ${CPPFLAGS}"
+
+prepare() {
+  cd $pkgname-$pkgver
+
+  # additional fixes
+  patch -Np1 -i $srcdir/fix-languages-cmake.patch
+}
+
+build() {
+  cmake \
+    -Wno-dev \
+    -S "${srcdir}/${pkgname}-${pkgver}" \
+    -B build \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DENABLE_MAN=ON \
+    -DENABLE_DOC=OFF \
+    -DENABLE_JAVASCRIPT=OFF \
+    -DENABLE_PHP=OFF \
+    -DENABLE_ZSTD=OFF \
+    -DENABLE_CJSON=OFF
+  make -C build
+}
+
+package() {
+  make DESTDIR="${pkgdir}" -C build install
+  install -Dm644 "${srcdir}"/$pkgname-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
+}