initial import

volumeicon/PKGBUILD

@@ -0,0 +1,48 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=volumeicon
+pkgver=0.5.1
+_debver=0.5.1+git20170117
+_debrel=1
+pkgrel=2
+pkgdesc='Volume control for the system tray'
+arch=('i686' 'x86_64')
+url='https://softwarebakery.com/maato/volumeicon.html'
+license=('GPL-3')
+depends=('alsa-lib' 'gtk')
+makedepends=('quilt' 'intltool')
+install=volumeicon.install
+source=(https://deb.debian.org/debian/pool/main/v/$pkgname/volumeicon_$_debver.orig.tar.xz
+        https://deb.debian.org/debian/pool/main/v/$pkgname/volumeicon_$_debver-$_debrel.debian.tar.xz
+        volumeicon.desktop)
+sha512sums=('30661325b7976f9c0087950fcf00efbb0bb43e10fc9949decf88aa2777ac060d5033136c6d4ed668f5f4c212488313d360bd6a36db0aa56b2e6fec60a561d7d9'
+            '1bb277c95fdf016531d6620abc1c6c13f8e135533bfe3a21f20aeea4a914e82ba1bb323ec7ad775eacd83d73226236409de72061ca891cfd3156aa6608a355cc'
+            '41c8cb37fea131c73a3340e216cd4f59ee6b4c7a98b7d1b96d5c02fa6584215ed9137483bb0a23181372413f2d41c652f0f53b88cf5f6da48b2a305bc6103d67')
+
+prepare() {
+  cd $pkgname-$_debver
+  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
+    # Debian patches
+    export QUILT_PATCHES=debian/patches
+    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
+    export QUILT_DIFF_ARGS='--no-timestamps'
+
+    mv "$srcdir"/debian .
+
+    quilt push -av
+  fi
+  ./autogen.sh
+}
+
+build() {
+  cd $pkgname-$_debver
+  ./configure --prefix=/usr --disable-notify
+  make
+}
+
+package() {
+  cd $pkgname-$_debver
+  make DESTDIR="$pkgdir" install
+  install -Dm644 "${srcdir}/volumeicon.desktop" -t "${pkgdir}/usr/share/applications/"
+  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
+}

volumeicon/volumeicon.desktop

@@ -0,0 +1,9 @@
+[Desktop Entry]
+Name=Volume Icon
+Comment=Lightweight volume control for the systray
+Exec=volumeicon
+Icon=multimedia-volume-control
+Type=Application
+Terminal=false
+StartupNotify=false
+Categories=GTK;AudioVideo;Audio;Mixer;

volumeicon/volumeicon.install

@@ -0,0 +1,7 @@
+post_install() {
+  # See FS#34239 for more information
+  echo 'If there are problems running volumeicon, try:'
+  echo 'rm -iv ~/.config/volumeicon/volumeicon'
+}
+
+# vim:set ts=2 sw=2 et: