initial import

vegastrike-engine/PKGBUILD

@@ -0,0 +1,40 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=vegastrike-engine
+pkgver=0.8.0
+pkgrel=1
+pkgdesc="A free and libre engine for spaceflight simulations"
+arch=('i686' 'x86_64')
+url='https://www.vega-strike.org/'
+license=('GPL-2')
+depends=('boost-libs' 'python' 'freeglut' 'gtk' 'libvorbis' 'openal' 'sdl' 'glu')
+makedepends=('cmake' 'boost')
+groups=('games')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/vegastrike/Vega-Strike-Engine-Source/archive/refs/tags/v${pkgver}.tar.gz")
+sha512sums=('22a2acf9a6028b30b18622c478bfacffc20a9cac407208fea89b7a6334f0d19e63e9663cb52a2fc518bc4ee25ed8ff9dad88880b1cdd937e232e377129fed091')
+
+build(){
+  # buildtype 'none' will fail the build
+  cmake \
+    -S Vega-Strike-Engine-Source-$pkgver/engine \
+    -B build \
+    -Wno-dev \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DENABLE_PIE=ON
+  make -C build
+}
+
+package() {
+  make -C build DESTDIR="$pkgdir" install
+
+  # correct package-structure
+  mv "$pkgdir/usr/bin" "$pkgdir/usr/games"
+  install -d "$pkgdir/usr/share/man/man1"
+  mv "$pkgdir/usr/share/man/"{vegasettings,vegastrike,vegastrike-engine,vsinstall,vslauncher}.1 "$pkgdir/usr/share/man/man1"
+  rm -rf "$pkgdir/usr/include"
+  rm -rf "$pkgdir/usr/lib"
+
+  # install license
+  install -Dm644 "$srcdir/Vega-Strike-Engine-Source-$pkgver/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname"
+}