initial import

trackballs/PKGBUILD

@@ -0,0 +1,42 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=trackballs
+pkgver=1.3.2
+pkgrel=2
+pkgdesc="Free and libre game where you guide a marble through a maze and avoid obstacles"
+arch=('i686' 'x86_64')
+license=('GPL-2')
+url='https://trackballs.github.io/'
+depends=('guile' 'sdl2_ttf' 'sdl2_image' 'sdl2_mixer' 'hicolor-icon-theme' 'gettext-tiny')
+makedepends=('cmake')
+groups=('games')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/trackballs/trackballs/archive/v${pkgver}.tar.gz"
+        "find_guile.patch"
+        "${pkgname}.desktop")
+sha512sums=('489b93cdf0e7941ffff545bfdafd665d2555a5367a282562bdcba3e1405d16110c84691117e0aa9f2c2561617c2a0bde82f186a972a1eaf53afa3405b02d4819'
+            '17a936d1d12eba850757d0e63a4a9457e1cdd5f73e3312b9cbaeecb35a17524775e04afb2b3f2650e117125c6c9036f622bc98c628d8c4942c4abaf54822375f'
+            'a6802bfe09c2a0a1c25f10ce6c3eac600a3e819716811d0a578c0458856d6bb63df181432c3bef69e5fc66d2dbdf9a784ff1ee6580f0010b3f46a71105156fa7')
+
+prepare() {
+  cd ${srcdir}/$pkgname-$pkgver
+  patch -p1 -i "${srcdir}/find_guile.patch"
+}
+
+build() {
+  cmake -B build \
+    -S $pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DTRACKBALLS_BIN_DIR=/usr/games \
+    -DTRACKBALLS_SHARE_DIR=/usr/share/games/$pkgname
+  make -C build
+}
+
+package() {
+  make -C build DESTDIR=${pkgdir} install
+
+  rm -rf "${pkgdir}/usr/share/applications"
+  install -Dm644 "${srcdir}/${pkgname}.desktop" -t "${pkgdir}/usr/share/applications"
+
+  install -Dm644 $pkgname-$pkgver/COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
+}