initial import

toxic/PKGBUILD

@@ -0,0 +1,42 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=toxic
+pkgver=0.16.0
+pkgrel=1
+pkgdesc="Commandline Tox client"
+arch=('i686' 'x86_64')
+url='https://github.com/JFreegman/toxic'
+license=('GPL-3')
+depends=('curl' 'qrencode' 'libx11' 'toxcore')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/JFreegman/toxic/archive/refs/tags/v${pkgver}.tar.gz"
+        "$pkgname.png"
+        "libre.patch")
+sha512sums=('94e8c61bff56533f384367270b5b946727e7cb6a3f928b312c47578b104a881fd344af829bbf4712a79ef65526ba75c84c335ef31685e97b4a7b03b96bd642b2'
+            '8ad6412bcfac81c797dfbfe9a10ed2e3ba8034fb3866838c344e7a73bd55146183ac91ceb11ced5b3eb254e0e8a6d0ae084767c41c0059da9bd83bf6d184c622'
+            'a22031d0d8147139b23253a13fc2c059500e23242110b3ecade262ccf2d8da33346b7b6867117b205f3b8ba80d6a9363b6c96f8daeee2ec7804631542139a365')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  patch -Np1 -i ${srcdir}/libre.patch
+  sed -i -e 's/Icon=utilities-terminal/Icon=toxic/g' \
+         misc/toxic.desktop
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  make PREFIX="/usr" \
+       USER_LDFLAGS="-lpthread" \
+       DISABLE_GAMES=1 \
+       DISABLE_AV=1 \
+       DISABLE_SOUND_NOTIFY=1 \
+       DISABLE_DESKTOP_NOTIFY=1 \
+       ENABLE_RELEASE=1
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  make PREFIX="/usr" DESTDIR="$pkgdir" USER_LDFLAGS="-lpthread" install
+  rm -rf $pkgdir/usr/share/$pkgname/sounds/
+  install -Dm644 $srcdir/$pkgname.png -t $pkgdir/usr/share/pixmaps/
+  install -Dm644 LICENSE -t $pkgdir/usr/share/licenses/$pkgname/
+}