initial import

tint2/PKGBUILD

@@ -0,0 +1,33 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=tint2
+pkgver=16.7
+pkgrel=1
+pkgdesc='Basic, good-looking task manager for WMs'
+arch=('i686' 'x86_64')
+url='https://gitlab.com/o9000/tint2/'
+license=('GPL-2')
+depends=('gtk2' 'imlib2' 'startup-notification')
+makedepends=('cmake' 'ninja')
+source=("https://deb.debian.org/debian/pool/main/t/${pkgname}/${pkgname}_${pkgver}.orig.tar.bz2"
+	"libre.patch")
+sha512sums=('92d3bb3b26fe356553b711727d86c46ab1530990e972791b10ddde57c7479ce983dda97bacb5dd37be1e846c767b00a0e36388271d5e6618552243c8e2a7fa43'
+	    '73f94892e1ff5ddfe5ab691c8d4241b92389affe72ea7dd35b7fdbfaeefd0fa13560c86cff1f08f5bb04ffa625079547c74fa44995785bbcd52f56e2216b126e')
+
+prepare() {
+  cd ${pkgname}-v${pkgver}/
+  patch -p1 -i ${srcdir}/libre.patch
+}
+
+build() {
+  cd ${pkgname}-v${pkgver}/
+  cmake -GNinja -DCMAKE_INSTALL_PREFIX=/usr/ -DENABLE_TINT2CONF=1
+  ninja
+}
+
+package() {
+  cd ${pkgname}-v${pkgver}/
+  DESTDIR=${pkgdir} ninja install
+  # Install licence file.
+  install -Dm644 COPYING -t ${pkgdir}/usr/share/licenses/${pkgname}/
+}