initial import

speex/PKGBUILD

@@ -0,0 +1,38 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=speex
+pkgver=1.2.0
+pkgrel=2
+pkgdesc="A free codec for free speech"
+arch=(i686 x86_64)
+url="https://speex.org/"
+license=(Modified-BSD)
+depends=(libogg speexdsp libsndio)
+source=(https://downloads.us.xiph.org/releases/$pkgname/$pkgname-$pkgver.tar.gz
+        sndio.patch)
+sha512sums=('7fe10838c7d1bafcbe42295b82b79262420dba793b8a4388e2f73a3007850b5572face1b5308d9f4e8d7dfc9cb1c016cbad88cd65b2892667986107ed946836b'
+            '265bee624bc1a88ac41cd67b43e7f9b08da74710c951d0a706b23e2081f598fda91cb333deea16af17d1d12fa77b15c6755c4f9c83e1954fef93ab8f8e5ac849')
+
+prepare() {
+  cd $pkgname-$pkgver
+  patch -p1 -i ../sndio.patch
+}
+
+build() {
+  export CPPFLAGS+=" -DUSE_SNDIO"
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --disable-static \
+    --enable-binaries # Must be given or configure won't use pkg-config correctly
+  make
+}
+
+check() {
+  cd $pkgname-$pkgver
+  make -k check
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}