initial import

snarf/PKGBUILD

@@ -0,0 +1,34 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=snarf
+pkgver=7.0
+_debver=$pkgver
+_debrel=6
+pkgrel=1
+pkgdesc="Command-line URL retrieval tool (http/ftp/gopher)"
+arch=('i686' 'x86_64')
+url="https://www.xach.com/snarf/"
+license=('GPL-2')
+depends=('glibc')
+source=("https://www.xach.com/snarf/download/source/${pkgname}-${pkgver}.tar.gz"
+        "https://deb.debian.org/debian/pool/main/s/snarf/snarf_${_debver}-${_debrel}.diff.gz")
+sha512sums=('311c3e4a1b32fd024da8a5c8167888f254608d538695e30b3c632c606f67d1e3d94d8c88deb7850f782f38412f1bfd9022b0ee780c8644655f0648ccf0a0354e'
+            'd3e6700de0c9a270293816f720ecd206e990f881b6726d7af97db6a006d2cac704d9f2f682735da9dd128c7a15521af44c6b5903b17c22f0a87d742f9c1eaf86')
+
+prepare() {
+  cd ${pkgname}-${pkgver}
+  patch -Np1 -i ${srcdir}/${pkgname}_${_debver}-${_debrel}.diff
+}
+
+build() {
+  cd ${pkgname}-${pkgver}
+  export CPPFLAGS=${CPPFLAGS/-D_FORTIFY_SOURCE=2/}
+  ./configure --prefix=/usr --mandir=/usr/share/man
+  make
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make DESTDIR="${pkgdir}" install
+  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
+}