initial import

scron/PKGBUILD

@@ -0,0 +1,43 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=scron
+pkgver=0.4
+pkgrel=1
+pkgdesc="Simple cron daemon"
+arch=('i686' 'x86_64')
+url='https://git.2f30.org/scron/'
+license=('Expat')
+provides=('cron')
+conflicts=('cron')
+install=$pkgname.install
+source=("https://dl.2f30.org/releases/${pkgname}-${pkgver}.tar.gz"
+        "fhs-compliant.patch"
+        "scrond.initd"
+        "scrond.run")
+sha512sums=('585c8dd1acab29d37890b62b4c8de2ae6a26bc67c3e95c1c8eaefc6672b6a1b0c3432a93b34d44eb693ba322f4b8f29495e1a825e87b376edb6c5c842da26f1f'
+            '7df5cb4d8f984b145d449ebb5f1ed4ee7c55567be56988c6765aae85be04c19220d42bbcf780e9c368be46f938e7a1219e50529bb8af442b96ecb36aadbeef53'
+            '5dc464a5c990bee0440339d2dc1cea330c973564d258ce28be966e82c7dd55375436667f5e9c59bd8ae069d8c88fed60bd7cbb41861b747dfb4c1e7d74a3293d'
+            'a1171a5c7d5bac1290af15f72ee9dc1dd43ced26b126478f01a517e27ef2a87e956a85466bf6d9962df700f7a66cc5d0e1ef5cf0877c76cbb2bec71e6897e7d4')
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+  rm crond.c
+  patch -Np1 -i ${srcdir}/fhs-compliant.patch
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  make
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  make DESTDIR="$pkgdir" PREFIX=/usr MANPREFIX=/usr/share/man install
+
+  # services
+  install -Dm755 "$srcdir/scrond.initd" "$pkgdir/etc/init.d/scrond"
+  install -Dm755 "$srcdir/scrond.run" "$pkgdir/etc/sv/scrond/run"
+
+  # license
+  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+}