initial import

sassc/PKGBUILD

@@ -0,0 +1,47 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=sassc
+pkgver=3.6.1
+_debver=3.6.1+20201027
+_debrel=1
+pkgrel=1
+pkgdesc="C implementation of Sass CSS preprocessor."
+arch=(i686 x86_64)
+url="https://github.com/sass/sassc"
+license=(Expat)
+depends=(libsass)
+makedepends=(quilt)
+source=($pkgname-$pkgver.tar.gz::https://github.com/sass/$pkgname/archive/$pkgver.tar.gz
+        https://deb.debian.org/debian/pool/main/s/sassc/sassc_$_debver-$_debrel.debian.tar.xz)
+sha512sums=('b6df8f481db0737ca08808c0849dcbd83e80799d883271d382607b7a74028153195f5f9c26768ffe1a9a92ee8c26be3c382ad7b3a5336eb6e4a0dad58132690e'
+            'bc1cd309f905625a04dcb78be9db2f04365fc7ede02dc20906af7167c1dd512223895fe05c0491d74f31afaf94fd328f11010f66be832cb566fb7bcb860c4ac7')
+
+prepare() {
+	cd $pkgname-$pkgver
+
+	if [[ $pkgver = ${_debver%+*} ]]; then
+		# Debian patches
+		export QUILT_PATCHES=debian/patches
+		export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
+		export QUILT_DIFF_ARGS='--no-timestamps'
+
+		mv "$srcdir"/debian .
+
+		quilt push -av
+	fi
+	autoreconf -i
+}
+
+build() {
+	cd $pkgname-$pkgver
+
+	./configure --prefix=/usr
+	make
+}
+
+package() {
+	cd $pkgname-$pkgver
+
+	make DESTDIR="$pkgdir/" install
+	install -D -m644 LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
+}