initial import

2025-06-22 20:39:04 -05:00
commit f8a70886f0
3428 changed files with 302546 additions and 0 deletions
--- a/rspamd/PKGBUILD
+++ b/rspamd/PKGBUILD
@@ -0,0 +1,143 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=rspamd
+pkgver=2.7
+pkgrel=4
+pkgdesc="Fast, free and libre spam filtering system"
+arch=('i686' 'x86_64')
+url='https://rspamd.com'
+license=('Apache-2.0')
+depends=('file' 'glib2' 'glibc' 'icu' 'jemalloc' 'libsodium' 'luajit' 'openblas'
+         'libressl' 'pcre' 'sqlite' 'zlib')
+makedepends=('cmake' 'ninja' 'perl' 'ragel')
+backup=('etc/rspamd/actions.conf'
+        'etc/rspamd/cgp.inc'
+        'etc/rspamd/common.conf'
+        'etc/rspamd/composites.conf'
+        'etc/rspamd/groups.conf'
+        'etc/rspamd/logging.inc'
+        'etc/rspamd/maps.d/dmarc_whitelist.inc'
+        'etc/rspamd/maps.d/maillist.inc'
+        'etc/rspamd/maps.d/mid.inc'
+        'etc/rspamd/maps.d/mime_types.inc'
+        'etc/rspamd/maps.d/redirectors.inc'
+        'etc/rspamd/maps.d/spf_dkim_whitelist.inc'
+        'etc/rspamd/maps.d/surbl-whitelist.inc'
+        'etc/rspamd/metrics.conf'
+        'etc/rspamd/modules.conf'
+        'etc/rspamd/modules.d/antivirus.conf'
+        'etc/rspamd/modules.d/arc.conf'
+        'etc/rspamd/modules.d/asn.conf'
+        'etc/rspamd/modules.d/chartable.conf'
+        'etc/rspamd/modules.d/clickhouse.conf'
+        'etc/rspamd/modules.d/dcc.conf'
+        'etc/rspamd/modules.d/dkim.conf'
+        'etc/rspamd/modules.d/dkim_signing.conf'
+        'etc/rspamd/modules.d/dmarc.conf'
+        'etc/rspamd/modules.d/elastic.conf'
+        'etc/rspamd/modules.d/emails.conf'
+        'etc/rspamd/modules.d/external_services.conf'
+        'etc/rspamd/modules.d/force_actions.conf'
+        'etc/rspamd/modules.d/forged_recipients.conf'
+        'etc/rspamd/modules.d/fuzzy_check.conf'
+        'etc/rspamd/modules.d/greylist.conf'
+        'etc/rspamd/modules.d/hfilter.conf'
+        'etc/rspamd/modules.d/http_headers.conf'
+        'etc/rspamd/modules.d/maillist.conf'
+        'etc/rspamd/modules.d/metadata_exporter.conf'
+        'etc/rspamd/modules.d/metric_exporter.conf'
+        'etc/rspamd/modules.d/mid.conf'
+        'etc/rspamd/modules.d/milter_headers.conf'
+        'etc/rspamd/modules.d/mime_types.conf'
+        'etc/rspamd/modules.d/multimap.conf'
+        'etc/rspamd/modules.d/mx_check.conf'
+        'etc/rspamd/modules.d/neural.conf'
+        'etc/rspamd/modules.d/once_received.conf'
+        'etc/rspamd/modules.d/p0f.conf'
+        'etc/rspamd/modules.d/phishing.conf'
+        'etc/rspamd/modules.d/ratelimit.conf'
+        'etc/rspamd/modules.d/rbl.conf'
+        'etc/rspamd/modules.d/regexp.conf'
+        'etc/rspamd/modules.d/replies.conf'
+        'etc/rspamd/modules.d/reputation.conf'
+        'etc/rspamd/modules.d/rspamd_update.conf'
+        'etc/rspamd/modules.d/spamassassin.conf'
+        'etc/rspamd/modules.d/spamtrap.conf'
+        'etc/rspamd/modules.d/spf.conf'
+        'etc/rspamd/modules.d/surbl.conf'
+        'etc/rspamd/modules.d/trie.conf'
+        'etc/rspamd/modules.d/url_redirector.conf'
+        'etc/rspamd/modules.d/whitelist.conf'
+        'etc/rspamd/options.inc'
+        'etc/rspamd/rspamd.conf'
+        'etc/rspamd/scores.d/fuzzy_group.conf'
+        'etc/rspamd/scores.d/headers_group.conf'
+        'etc/rspamd/scores.d/hfilter_group.conf'
+        'etc/rspamd/scores.d/mime_types_group.conf'
+        'etc/rspamd/scores.d/mua_group.conf'
+        'etc/rspamd/scores.d/phishing_group.conf'
+        'etc/rspamd/scores.d/policies_group.conf'
+        'etc/rspamd/scores.d/rbl_group.conf'
+        'etc/rspamd/scores.d/statistics_group.conf'
+        'etc/rspamd/scores.d/subject_group.conf'
+        'etc/rspamd/scores.d/surbl_group.conf'
+        'etc/rspamd/scores.d/whitelist_group.conf'
+        'etc/rspamd/settings.conf'
+        'etc/rspamd/statistic.conf'
+        'etc/rspamd/worker-controller.inc'
+        'etc/rspamd/worker-fuzzy.inc'
+        'etc/rspamd/worker-normal.inc'
+        'etc/rspamd/worker-proxy.inc')
+install=$pkgname.install
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/rspamd/rspamd/archive/refs/tags/${pkgver}.tar.gz"
+        "$pkgname.initd"
+        "$pkgname.confd"
+        "$pkgname.run")
+sha512sums=('8779771baf85ef6ca1d7d2180429072ab1547ab834b073ee9222dcc6494efdd0a23f5e7ac52a777c23fd89296769f5b6f182593e714097c6f11ca7c9165e4ba7'
+            'eb18a8d357ac17f6ef645d7856df9a6fe2d445538368671b723636e45450f98d27f29df8726627c0861be4ce74670cb0a4e101fc948ba0afa362725c9f5ac833'
+            '038250d7b1cf45a5bc656a8f54d7ad1bd61996eccbe2f35a5dbf3d00fb4bf3fc09e13833810fbaa40c0d9e1b00b2fccfddd7e9215fac518a1df065c7929c86b3'
+            '02178d47965c48e0d7b544218fb96c4511df9c76543a47cf3f55e561a9676a724403ce60c5d371419b846cc1f5910205ee2b444ee657de51e7db95607ec377e7')
+
+build() {
+  cmake -S ${pkgname}-${pkgver} \
+        -B build \
+        -G Ninja \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCONFDIR=/etc/rspamd \
+        -DDBDIR=/var/lib/rspamd \
+        -DLOGDIR=/var/log/rspamd \
+        -DRUNDIR=/run/rspamd \
+        -DRSPAMD_USER=rspamd \
+        -DNO_SHARED=ON \
+        -DWANT_SYSTEMD_UNITS=OFF \
+        -DENABLE_HYPERSCAN=OFF \
+        -DENABLE_JEMALLOC=ON \
+        -DENABLE_OPTIMIZATION=ON
+  cmake --build build
+}
+
+package() {
+  DESTDIR="${pkgdir}" cmake --build build --target install
+
+  local path="${pkgdir}"/usr/bin
+  for file in rspamd rspamc rspamadm;
+  do
+    rm "$path"/$file
+    mv "$path"/$file-$pkgver "$path"/$file
+  done
+
+  mv "$path"/rspamd_stats "$path"/rspamd-stats
+  install -d "${pkgdir}"/usr/sbin
+  mv "${pkgdir}"/usr/bin/$pkgname "${pkgdir}"/usr/sbin/
+  rm "${pkgdir}"/etc/rspamd/modules.d/{history_redis,redis}.conf
+
+  install -dm750 "${pkgdir}"/var/lib/$pkgname
+  install -dm750 "${pkgdir}"/var/log/$pkgname
+  install -dm755 "${pkgdir}"/etc/$pkgname/local.d/maps.d
+
+  install -Dm755 "${srcdir}/$pkgname.initd" "${pkgdir}/etc/init.d/$pkgname"
+  install -Dm644 "${srcdir}/$pkgname.confd" "${pkgdir}/etc/conf.d/$pkgname"
+  install -Dm755 "${srcdir}/$pkgname.run" "${pkgdir}/etc/sv/$pkgname/run"
+
+  install -Dm644 ${pkgname}-${pkgver}/LICENSE.md -t "${pkgdir}"/usr/share/licenses/$pkgname
+}