initial import

qtcreator/PKGBUILD

@@ -0,0 +1,52 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=qtcreator
+pkgver=4.14.1
+_clangver=11.0.0
+pkgrel=3
+pkgdesc="Lightweight, cross-platform integrated development environment"
+arch=('i686' 'x86_64')
+url='https://www.qt.io'
+license=('custom:GPL-3+Qt-Company-GPL-Exception-1.0')
+depends=('qt-tools' 'qt-quickcontrols' 'qt-quickcontrols2' 'qt-svg' 'qt-quick3d' 'qt-serialport'
+         clang=$_clangver 'clazy' 'syntax-highlighting' 'yaml-cpp')
+makedepends=('cmake' 'llvm' 'python')
+options=(docs)
+optdepends=('qt-doc: integrated Qt documentation'
+            'qt-examples: welcome page examples'
+            'qt-translations: for other languages'
+            'gdb: debugger'
+            'cmake: cmake project support'
+            'qbs: QBS project support'
+            'x11-ssh-askpass: ssh support'
+            'git-legacy: git support'
+            'mercurial: mercurial support'
+            'bzr: bazaar support'
+            'valgrind: analyze support')
+source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/q/qtcreator/qtcreator_${pkgver}.orig.tar.xz")
+sha512sums=('09c18776bab2958b8dd7f61fa793964d12ba54f20167277e5cbcabfc040ecc92d3ec8e96eb8e77c1899998a6c82cce6b316cc709738c6262622aa80f0f9989e8')
+
+prepare() {
+  cd qt-creator-opensource-src-$pkgver
+
+  # use system qbs
+  rm -r src/shared/qbs
+  # fix linking to clang
+  sed -e 's|clangFormat|clang-cpp|' -i src/plugins/clangformat/CMakeLists.txt
+  # remove unfree parts
+  rm -rv src/plugins/help/webenginehelpviewer.{cpp,h}
+}
+
+build() {
+  cmake \
+    -B build \
+    -S qt-creator-opensource-src-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DWITH_DOCS=ON
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+  install -Dm644 qt-creator-opensource-src-$pkgver/LICENSE.GPL3-EXCEPT -t "$pkgdir"/usr/share/licenses/$pkgname
+}