initial import

qt-webkit/PKGBUILD

@@ -0,0 +1,65 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=qt-webkit
+_pkgver=5.212.0-alpha4
+pkgver=${_pkgver/-/}
+_debver=5.212.0~alpha4
+_debrel=11
+pkgrel=6
+arch=(i686 x86_64)
+url='https://www.qt.io'
+license=(LGPL-2.1)
+pkgdesc="Classes for a WebKit2 based implementation and a new QML API"
+depends=(qt-sensors qt-webchannel libxslt libxcomposite gst-plugins-base hyphen)
+makedepends=(cmake ruby gperf python qt-tools quilt)
+replaces=(qt5-webkit qt5-webkit-ng)
+conflicts=(qt5-webkit qt5-webkit-ng)
+provides=(qt5-webkit qt5-webkit-ng)
+source=("https://github.com/qtwebkit/qtwebkit/releases/download/qtwebkit-$_pkgver/qtwebkit-$_pkgver.tar.xz"
+        "https://deb.debian.org/debian/pool/main/q/qtwebkit-opensource-src/qtwebkit-opensource-src_$_debver-$_debrel.debian.tar.xz"
+        '0001-Let-Bison-generate-the-header-directly-to-fix-build-.patch')
+sha512sums=('33f11270bd030599beff9c1983a6c5ff2d61f407cc8a6825f7f405d46f9184c720fc7f60c7359f08f828db96a2170092875066a0d5c0a21ff09bc48a2603fbf6'
+            '67ef6c01469d56f75ff813165df00656ec3893c30cbbcd027f0e2a51f017dfed9446df775080ea6dc2ff4f19b5b6a5a0c6d6c0708e147e0c1ac1282939578d6d'
+            '853142d8a07d387b8d2e345fd132e63f5f59a4f09641af765911a9cd54567bf9f3eb918dc22681e255e210a795e2bacc23550a0e75e0782123e90ab73723c6ba')
+
+prepare() {
+  cd qtwebkit-$_pkgver
+
+  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
+    # Debian patches
+    export QUILT_PATCHES=debian/patches
+    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
+    export QUILT_DIFF_ARGS='--no-timestamps'
+
+    mv "$srcdir"/debian .
+
+    # Doesn't apply
+    rm -v debian/patches/bison_3.7.diff || true
+
+    quilt push -av
+  fi
+
+  # let bison generate the header directly, to fix build with bison 3.7
+  patch -p1 -i $srcdir/0001-Let-Bison-generate-the-header-directly-to-fix-build-.patch
+}
+
+build() {
+  mkdir -p ./build && cd build
+  cmake ../qtwebkit-$_pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG" \
+    -DPORT=Qt \
+    -DENABLE_TOOLS=OFF \
+    -DENABLE_GEOLOCATION=OFF \
+    -DSKIP_DWZ=ON \
+    -DUSE_WOFF2=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+
+  # install license
+  install -Dm644 $srcdir/qtwebkit-$_pkgver/LICENSE.LGPLv21 -t $pkgdir/usr/share/licenses/$pkgname
+}