initial import

qbs/PKGBUILD

@@ -0,0 +1,44 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=qbs
+pkgver=1.18.0
+_debver=1.18.0
+_debrel=5
+pkgrel=1
+pkgdesc="Cross platform build tool"
+arch=('i686' 'x86_64')
+url='https://wiki.qt.io/Qbs'
+license=('LGPL-3')
+depends=('qt-script')
+makedepends=('cmake' 'quilt')
+source=(https://download.qt.io/official_releases/qbs/$pkgver/qbs-src-$pkgver.tar.gz
+        https://deb.debian.org/debian/pool/main/q/qbs/qbs_$_debver-$_debrel.debian.tar.xz)
+sha512sums=('bdef30200c7e74749c363b1d68232fd90d1dfc998722bee0e058ffcaff8e003599e0404b49f86cbeae098d59ccb5663316db5094d77b50a217fcf4ab5ae64d83'
+            '977db7c59fdb3e56b0477b62cfeb3fc1a4dd9b6e0c7c8783594f2f29948482a608486da43cffa8c5cc67956a21153d1d71802a9989744dc81725f88cc59e9c03')
+
+prepare() {
+  cd $pkgname-src-$pkgver
+  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
+    # Debian patches
+    export QUILT_PATCHES=debian/patches
+    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
+    export QUILT_DIFF_ARGS='--no-timestamps'
+
+    mv "$srcdir"/debian .
+
+    quilt push -av
+  fi
+}
+
+build() {
+  cmake -B build -S $pkgname-src-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DWITH_TESTS=OFF \
+    -DQBS_LIBEXEC_INSTALL_DIR=lib/qbs
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+  install -Dm644 "$srcdir/$pkgname-src-$pkgver/LICENSE.LGPLv3" -t "${pkgdir}/usr/share/licenses/$pkgname"
+}