initial import

python-zope-interface/PKGBUILD

@@ -0,0 +1,42 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgbase=python-zope-interface
+pkgname=('python-zope-interface' 'tauthon-zope-interface')
+pkgver=5.4.0
+pkgrel=2
+license=('Zope-2.1')
+arch=('i686' 'x86_64')
+url='https://pypi.python.org/pypi/zope.interface'
+makedepends=('python-setuptools' 'tauthon-setuptools')
+source=("https://pypi.io/packages/source/z/zope.interface/zope.interface-$pkgver.tar.gz")
+sha512sums=('ef15d63397e05ad9fc44b2d5d786b0399b6973bb5f4866fab839ff612756f3157f2099d0f5c0469b574a5c8b5920a7c2a5c6eab8e8f84c24d5c43e816669bffe')
+
+prepare() {
+  cp -a zope.interface-${pkgver}{,-py2}
+}
+
+build() {
+  cd "$srcdir"/zope.interface-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/zope.interface-$pkgver-py2
+  tauthon setup.py build
+}
+
+package_python-zope-interface() {
+  pkgdesc="Zope Interfaces for Python"
+  depends=('python')
+
+  cd zope.interface-$pkgver
+  python setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE.txt -t $pkgdir/usr/share/licenses/$pkgname
+}
+
+package_tauthon-zope-interface(){
+  pkgdesc="Zope Interfaces for tauthon"
+  depends=('tauthon')
+
+  cd zope.interface-$pkgver-py2
+  tauthon setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE.txt -t $pkgdir/usr/share/licenses/$pkgname
+}