initial import

python-pylibacl/PKGBUILD

@@ -0,0 +1,46 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+_pkgbase=pylibacl
+pkgname=python-$_pkgbase
+pkgver=0.6.0
+_debver=$pkgver
+_debrel=1
+pkgrel=2
+pkgdesc="A python extension module that allows you to manipulate the POSIX.1e ACLs."
+arch=('i686' 'x86_64')
+url='https://pylibacl.k1024.org/'
+license=('LGPL-2.1')
+depends=('python')
+makedepends=('python-setuptools' 'quilt')
+source=("https://pylibacl.k1024.org/downloads/${_pkgbase}-${pkgver}.tar.gz"
+        "https://deb.debian.org/debian/pool/main/p/python-pylibacl/python-pylibacl_${_debver}-${_debrel}.debian.tar.xz")
+sha512sums=('49e491589e06460fdd89307c754b2d99533ac857b187797b10a2a5aa1692c3401400d9d6e22cdb2369e5c34d91875133cf2d094226def837c603094745cbf904'
+            '84fa67ee405b18169925ae5e918e170dbf256c7a35b90ba9c69cdad3064106f1f2b2cf46d0ee1671745f81ffb2599425c5c50850a4aed5d1c92ca51708c7994c')
+
+prepare() {
+  cd "${srcdir}/${_pkgbase}-${pkgver}"
+  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
+    # Debian patches
+    export QUILT_PATCHES=debian/patches
+    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
+    export QUILT_DIFF_ARGS='--no-timestamps'
+
+    mv "$srcdir"/debian .
+
+    # Doesn't apply
+    rm -v debian/patches/python-pylibacl_hurd.patch || true
+
+    quilt push -av
+  fi
+}
+
+build() {
+  cd "${srcdir}/${_pkgbase}-${pkgver}"
+  python setup.py build
+}
+
+package() {
+  cd "${srcdir}/${_pkgbase}-${pkgver}"
+  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
+}