initial import

python-m2crypto/PKGBUILD

@@ -0,0 +1,47 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgbase=python-m2crypto
+pkgname=('python-m2crypto' 'tauthon-m2crypto')
+pkgver=0.36.0
+pkgrel=2
+arch=('i686' 'x86_64')
+url='https://pypi.python.org/pypi/M2Crypto'
+license=('Expat')
+makedepends=('python' 'python-setuptools' 'tauthon' 'tauthon-setuptools' 'swig')
+source=("https://gitlab.com/m2crypto/m2crypto/-/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz"
+        "libressl.patch")
+sha512sums=('7bd458d068859cb122f4c9d4951ea3e8d186e22b99533c5b2d9fac6b045a603f0647a363f64aba351fc6f0fa87f4dff1536d365da9074627e124ad271e22710f'
+            'cfc7c3cb007f573f10aa31dbd7cb37043b2055d925b4151a1f2dafe154097de320a848e410e7dcc122e610894e385272a547c22bdc48a62ede35ba12c9cca96e')
+
+prepare() {
+  mv m2crypto-${pkgver}-* m2crypto-${pkgver}
+  cd "$srcdir/m2crypto-$pkgver"
+  patch -p0 -i "$srcdir/libressl.patch"
+  cp -a "$srcdir/m2crypto-$pkgver"{,-tauthon}
+}
+
+build(){
+  cd "$srcdir/m2crypto-$pkgver"
+  python setup.py build
+
+  cd "$srcdir/m2crypto-$pkgver-tauthon"
+  tauthon setup.py build
+}
+
+package_python-m2crypto() {
+  pkgdesc="A crypto and SSL toolkit for Python"
+  depends=('python' 'libressl')
+
+  cd "${srcdir}/m2crypto-${pkgver}"
+  python setup.py install --root="${pkgdir}/" --optimize=1 --skip-build
+  install -Dm644 LICENCE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+package_tauthon-m2crypto() {
+  pkgdesc="A crypto and SSL toolkit for Tauthon"
+  depends=('tauthon' 'libressl' 'tauthon-typing')
+
+  cd "${srcdir}/m2crypto-${pkgver}-tauthon"
+  tauthon setup.py install --root="${pkgdir}/" --optimize=1 --skip-build
+  install -Dm644 LICENCE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}