initial import

pwgen/PKGBUILD

@@ -0,0 +1,46 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=pwgen
+pkgver=2.08
+_debver=$pkgver
+_debrel=2
+pkgrel=2
+pkgdesc='Password generator for creating easily memorable passwords'
+arch=('i686' 'x86_64')
+url='https://sourceforge.net/projects/pwgen/'
+license=('GPL-2')
+depends=('glibc')
+makedepends=('quilt')
+source=("https://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.gz"
+        "https://deb.debian.org/debian/pool/main/p/pwgen/pwgen_$_debver-$_debrel.debian.tar.xz")
+sha512sums=('4a930dc7d4c58a4434209db30c54629d76fce57d0fd5767cd7894168bb1a5b85eaae6734a982b0f4e0640540c366ce27ad84860ff2c406dea3f5902b5bb54255'
+            '7671297990f0af3dfd6aba6e39e358e4e747d1eadcf54010f66d657b8988a383b0e9887ca3edeffc09c5af097383d8f2110b21b0d356ef869166d0358f8c36e5')
+
+prepare() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
+    # Debian patches
+    export QUILT_PATCHES=debian/patches
+    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
+    export QUILT_DIFF_ARGS='--no-timestamps'
+
+    rm -rf ./debian
+    mv "$srcdir"/debian .
+
+    quilt push -av
+  fi
+  autoconf
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  ./configure \
+    --prefix=/usr \
+    --mandir=/usr/share/man
+  make
+}
+
+package() {
+  make -C "$pkgname-$pkgver" DESTDIR="$pkgdir" install
+  install -Dm644 "${srcdir}/$pkgname-$pkgver/debian/copyright" -t "$pkgdir"/usr/share/licenses/$pkgname/
+}