initial import

plib/PKGBUILD

@@ -0,0 +1,38 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=plib
+pkgver=1.8.5
+pkgrel=1
+pkgdesc='Set of libraries to write games and other realtime interactive applications'
+arch=('i686' 'x86_64')
+url="http://plib.sourceforge.net/"
+license=('GPL-2')
+makedepends=('mesa-libgl' 'libxi' 'libxmu')
+source=(http://plib.sourceforge.net/dist/$pkgname-$pkgver.tar.gz
+        'config.guess::https://git.savannah.gnu.org/gitweb/?p=config.git;a=blob_plain;f=config.guess;hb=HEAD'
+        'config.sub::https://git.savannah.gnu.org/gitweb/?p=config.git;a=blob_plain;f=config.sub;hb=HEAD')
+options=('staticlibs')
+sha512sums=('17154cc77243fe576c2bcbcb0285b98aef1a0634658f5473e95fe0ac8fa3ed477dbe5620e44ccf0b7cc616f812af0cd44d6fcbba0c563180d3b61c9d6f158e1d'
+            'SKIP'
+            'SKIP')
+
+prepare() {
+  cd ${srcdir}/$pkgname-$pkgver
+
+  cp ../config.guess .
+  cp ../config.sub .
+}
+
+build() {
+  cd ${srcdir}/$pkgname-$pkgver
+
+  CXXFLAGS=-fPIC CFLAGS=-fPIC LDFLAGS=-fPIC ./configure --prefix=/usr
+  make
+}
+
+package() {
+  cd ${srcdir}/$pkgname-$pkgver
+
+  make DESTDIR="${pkgdir}" install
+  install -D -m644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
+}