initial import

perl-test-most/PKGBUILD

@@ -0,0 +1,33 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=perl-test-most
+_realpkgname=Test-Most
+pkgver=0.37
+pkgrel=1
+pkgdesc="Most commonly needed test functions and features"
+arch=('any')
+url='https://metacpan.org/release/Test-Most'
+license=('GPL-1')
+depends=('perl' 'perl-exception-class' 'perl-test-deep' 'perl-test-differences'
+         'perl-test-exception' 'perl-test-warn')
+options=(!emptydirs)
+_archive="$_realpkgname-$pkgver"
+source=("https://cpan.perl.org/modules/by-module/${_realpkgname%-*}/$_archive.tar.gz"
+        "LICENSE")
+sha512sums=('133dbb9815884fbecd65520dd2f2d43a761439c33f7d32ffdfc80ed3d3e05fb563dca420cf5445e61382735a048c467b35b5c160b1013b5f5c7616be00aa328d'
+            'e8457ed83eec98751713ffe6b8edf64bd0fb0959065184f7de6230495a9e3c66b137ae3e3164d7c81d98e979c1d2bc63b8b8d1106d15816d26e9f0582688b6ae')
+
+build() {
+  cd "$_archive"
+  unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
+  export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
+  perl Makefile.PL
+  make
+}
+
+package() {
+  cd "$_archive"
+  unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
+  make install INSTALLDIRS=vendor DESTDIR="$pkgdir"
+  install -Dm644 "$srcdir/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname"
+}