initial import

perl-locale-gettext/PKGBUILD

@@ -0,0 +1,41 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=perl-locale-gettext
+_realname=Locale-gettext
+pkgver=1.07
+pkgrel=3
+pkgdesc="Permits access from Perl to the gettext() family of functions"
+arch=('i686' 'x86_64')
+license=('GPL-1')
+url="https://search.cpan.org/dist/${_realname}/"
+depends=('gettext-tiny' 'perl')
+options=(!emptydirs)
+source=("https://search.cpan.org/CPAN/authors/id/P/PV/PVANDRY/${_realname}-${pkgver}.tar.gz"
+        'COPYING')
+sha512sums=('d3716a597d586ee2ff29472ca7b13aaf67770299de31e5f12abafebc879bbe4a1e1dbc0025cf4f3dc29992955f26cffc3be387d974c3911af095d5b49e67a1c6'
+            'e239b539f2c46c1ae3da87c4983a0fda67dc8ae622d607b507b5c523af3bdf99e7bea8931e3a7c6007910bfe9e21a761e03e8203de95b5aceea425a97d0a84c9')
+
+build() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+
+  # install module in vendor directories.
+  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
+  make
+}
+
+check() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+
+  make test
+}
+
+package() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+  make install DESTDIR="${pkgdir}"
+
+  install -Dm644 "${srcdir}/COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
+
+  # remove perllocal.pod and .packlist
+  find "${pkgdir}" -name perllocal.pod -delete
+  find "${pkgdir}" -name .packlist -delete
+}