initial import

perl-lchown/PKGBUILD

@@ -0,0 +1,36 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=perl-lchown
+pkgver=1.01
+_debver=$pkgver
+_debrel=4
+pkgrel=2
+pkgdesc="Library for using the lchown(2) system-call from Perl"
+arch=('i686' 'x86_64')
+license=('GPL-1')
+options=(!emptydirs)
+depends=('perl')
+makedepends=('perl-module-build')
+url='https://metacpan.org/release/Lchown'
+source=("https://cpan.metacpan.org/authors/id/N/NC/NCLEATON/Lchown-${pkgver}.tar.gz"
+        "COPYING::https://metadata.ftp-master.debian.org/changelogs//main/libl/liblchown-perl/liblchown-perl_${_debver}-${_debrel}_copyright")
+sha512sums=('f3b7bf7b3b71a7d92449d4ae8249d76b456869e48105db401a49f39f687ee5d97e079485fb2bbaae991a3a27d408959fc132b843c6f69487eeb2958c85f683a8'
+            '5492d14a0a5a5756a38151b0add341bf69adf2a09b5852bd29eb41c439e5a7d390e32a0d4948b3cb3f88753e9f4249fb54bb994ca04bde8fa80375beb42885f5')
+
+build() {
+  export PERL_MM_USE_DEFAULT=1 PERL5LIB="" \
+         PERL_AUTOINSTALL=--skipdeps \
+         PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='"$pkgdir"'" \
+         PERL_MB_OPT="--installdirs vendor --destdir '"$pkgdir"'" \
+         MODULEBUILDRC=/dev/null
+  cd "${srcdir}/Lchown-${pkgver}"
+  /usr/bin/perl Build.PL
+  ./Build
+}
+
+package() {
+  cd "${srcdir}/Lchown-${pkgver}"
+  ./Build install
+  find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
+  install -Dm644 "${srcdir}/COPYING" -t "$pkgdir/usr/share/licenses/$pkgname"
+}