initial import

perl-event-execflow/PKGBUILD

@@ -0,0 +1,34 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=perl-event-execflow
+_realname=Event-ExecFlow
+pkgver=0.64
+pkgrel=1
+pkgdesc="Framework for perl-events"
+arch=('any')
+license=('GPL-1')
+url='https://www.exit1.org/Event-ExecFlow/'
+depends=('perl-anyevent' 'perl-libintl-perl' 'perl')
+options=('!emptydirs')
+source=("https://search.cpan.org/CPAN/authors/id/J/JR/JRED/${_realname}-${pkgver}.tar.gz"
+        "LICENSE")
+sha512sums=('dab795481e3f85ecde70e330eda10c8d09eb310d3325945364eebc1d70521f094b1f6afc311aff4b662cbefd96e0170bfb72f284296654088b747a139bfe7b5d'
+            'e239b539f2c46c1ae3da87c4983a0fda67dc8ae622d607b507b5c523af3bdf99e7bea8931e3a7c6007910bfe9e21a761e03e8203de95b5aceea425a97d0a84c9')
+
+build() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+  # install module in vendor directories.
+  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
+  make
+}
+
+package() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+  make install DESTDIR="${pkgdir}/"
+
+  # remove perllocal.pod and .packlist
+  find "${pkgdir}" -name perllocal.pod -delete
+  find "${pkgdir}" -name .packlist -delete
+
+  install -Dm644 "$srcdir/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname"
+}