initial import

pangox-compat/PKGBUILD

@@ -0,0 +1,40 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=pangox-compat
+pkgver=0.0.2
+pkgrel=1
+pkgdesc="X Window System font support for Pango"
+arch=('i686' 'x86_64')
+url='http://www.pango.org/'
+license=('LGPL-2')
+depends=('pango')
+source=("https://gitlab.gnome.org/Archive/pangox-compat/-/archive/${pkgver}/pangox-compat-${pkgver}.tar.gz"
+        "disable-shaper.patch")
+sha512sums=('8e7ccec3a84fcc91400f5f42da3e39967bb9592078e69674cfc9d2686d03925be2b9a6f77a8a44395dc68b4b987ae0d27f12556f9e7d31b9bdffd4969a36ea42'
+            'f8533aad00e912f4db4732d78ad93c79d460df75777a6ae1e907b177af4cb178e672a4968b333d68af053c50f2b1bbe5fae8c5387f7daccb2b2e6224e3121d46')
+
+prepare() {
+  cd ${pkgname}-${pkgver}
+  patch -Nup1 -i '../disable-shaper.patch'
+}
+
+build() {
+  cd ${pkgname}-${pkgver}
+
+  if [ ! -s 'Makefile' ]; then
+    NOCONFIGURE=1 ./autogen.sh
+    ./configure \
+      --prefix=/usr \
+      --sysconfdir=/etc \
+      --localstatedir=/var \
+      --disable-static
+    sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  fi
+  make
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make -j1 DESTDIR="${pkgdir}" install
+  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
+}

pangox-compat/disable-shaper.patch

@@ -0,0 +1,15 @@
+--- pangox-compat/pangox.c.orig	2020-05-04 18:31:53.421197064 -0400
++++ pangox-compat/pangox.c	2020-05-04 18:32:41.251146923 -0400
+@@ -277,11 +277,11 @@ pango_x_font_class_init (PangoXFontClass
+   object_class->finalize = pango_x_font_finalize;
+   object_class->dispose = pango_x_font_dispose;
+ 
+   font_class->describe = pango_x_font_describe;
+   font_class->get_coverage = pango_x_font_get_coverage;
+-  font_class->find_shaper = pango_x_font_find_shaper;
++  /* font_class->find_shaper = pango_x_font_find_shaper; */
+   font_class->get_glyph_extents = pango_x_font_get_glyph_extents;
+   font_class->get_metrics = pango_x_font_get_metrics;
+   font_class->get_font_map = pango_x_font_get_font_map;
+ }
+