initial import

openrsync/PKGBUILD

@@ -0,0 +1,39 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=openrsync
+pkgver=0.5.0
+pkgrel=1
+pkgdesc="OpenBSD implementation of rsync"
+arch=('i686' 'x86_64')
+url='https://github.com/kristapsdz/openrsync'
+license=('ISC')
+depends=('glibc')
+source=("${pkgname}-${pkgver}.zip::https://github.com/kristapsdz/openrsync/archive/refs/heads/master.zip")
+sha512sums=('022dc0d558e06dfacdc64a6f4a9497d159fae2560fa908d333ba6de979cffa6bbec75f5f189084333a6a55a826dd40b2b0b7dc5304f486576324b60b75e4052d')
+
+prepare() {
+  mv "${pkgname}-master" "${pkgname}-${pkgver}"
+  cd "${pkgname}-${pkgver}"
+
+  # Remove forced debug
+  sed -i 's/CFLAGS="${CFLAGS} -g /CFLAGS="${CFLAGS} /' configure
+
+  # LDFLAGS
+  sed -i 's/$(CC) -o $@ /$(CC) $(LDFLAGS) -o $@ /' Makefile
+
+  # Fix install permissions
+  sed -i 's/"${INSTALL} -m 0555"/"${INSTALL} -m755"/' configure
+  sed -i 's/"${INSTALL} -m 0444"/"${INSTALL} -m644"/' configure
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  ./configure LDFLAGS="$LDFLAGS" MANDIR=/usr/share/man PREFIX=/usr
+  make
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  make DESTDIR="$pkgdir" install
+  install -Dm644 LICENSE.md -t "$pkgdir/usr/share/licenses/$pkgname"
+}