initial import

openal/PKGBUILD

@@ -0,0 +1,63 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgbase=openal
+pkgname=(openal openal-examples)
+pkgver=1.19.1
+pkgrel=6
+pkgdesc="Cross-platform 3D audio library, software implementation"
+arch=(i686 x86_64)
+url="https://github.com/kcat/openal-soft"
+license=(LGPL-2)
+makedepends=(libsndio fluidsynth qt-base sdl2 sdl_sound ffmpeg
+             cmake ninja)
+source=("https://github.com/kcat/openal-soft/archive/refs/tags/openal-soft-$pkgver.tar.gz"
+        'alsoft_hyperbolabsd.conf' 'alsoft_gnu+linux.conf')
+sha512sums=('4a64cc90ddeaa3773610b0bc8023d231100f3396f3fc5bd079db81600f80a789c75e6af03391bfc78a903c96bb71f8052a9ae802ea81422028e5b12b7eb6c47b'
+            '8f4dfe426317003313a925ec2de095b01685d926bd333da5e5b3bb305c9ccc7b838ffe40646c83f7b4e5abd9d9f67165c488fc3bf9b106784dbb8e6c270ff00d'
+            'a55c887d380f80f8fed67862f3c46cd395a6415ba3d1153b5d82e8b367848670a80925fbb1b301588baffc9620de00b6d52d08f2228527ad094ca453062b82b2')
+
+prepare() {
+  mkdir build examples
+}
+
+build() {
+  cd build
+  cmake ../$pkgbase-soft-$pkgbase-soft-$pkgver -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DALSOFT_REQUIRE_SNDIO=On
+  ninja
+}
+
+package_openal() {
+  depends=(libsndio)
+  optdepends=('qt-base: alsoft-config GUI Configurator'
+              'fluidsynth: MIDI rendering'
+              'sndio: sndio audio backend')
+  install=openal.install
+  backup=(etc/openal/alsoft.conf)
+
+  DESTDIR="$pkgdir" ninja -C build install
+  install -dm755 "$pkgdir/usr/share/doc/openal"
+  install -Dm644 $pkgbase-soft-$pkgbase-soft-$pkgver/docs/* "$pkgdir/usr/share/doc/openal"
+  install -Dm644 $pkgbase-soft-$pkgbase-soft-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
+
+  if [ "$(uname -s)" = 'HyperbolaBSD' ]; then
+    install -Dm644 "$srcdir/alsoft_hyperbolabsd.conf" "$pkgdir/etc/openal/alsoft.conf"
+  elif [ "$(uname -o)" = 'GNU/Linux' ]; then
+    install -Dm644 "$srcdir/alsoft_gnu+linux.conf" "$pkgdir/etc/openal/alsoft.conf"
+  fi
+
+  ### Split openal-examples
+  mv "$pkgdir"/usr/bin/al{ffplay,hrtf,latency,loopback,multireverb,play,record,reverb,stream,tonegen} examples/
+}
+
+package_openal-examples() {
+  pkgdesc+=" (example programs)"
+  depends=("openal=$pkgver-$pkgrel" sdl2 sdl_sound ffmpeg)
+
+  mkdir -p "$pkgdir/usr/bin"
+  mv examples/* "$pkgdir/usr/bin/"
+  install -Dm644 $pkgbase-soft-$pkgbase-soft-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
+}