initial import

oolite/PKGBUILD

@@ -0,0 +1,46 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=oolite
+pkgver=1.90
+pkgrel=2
+pkgdesc="A free and libre space-sim for travellers, traders, pirates and more"
+arch=('i686' 'x86_64')
+url='https://github.com/OoliteProject/oolite'
+license=('GPL-2' 'Modified-BSD' 'zlib' 'CC-BY-SA-3.0')
+depends=('espeak' 'gnustep-base' 'sdl_mixer' 'sdl_image' 'glu' 'nspr' 'openal')
+makedepends=('gnustep-make' 'curl' 'zip' 'mesa' 'gcc-objc')
+groups=('games')
+source=("https://github.com/OoliteProject/oolite/releases/download/$pkgver/oolite-source-$pkgver.tar.bz2"
+        "oolite")
+sha512sums=('8a4900087d43a9e7b0b061096c5981cc1d9de65a70ed16d6b33cd1a5a56e2f6b043a10a1e2088013da6352778617273134f324f825ae98c23f73bfb15cea7dab'
+            'e94bef74f1d8192a7b0fb9dc1c3ce17f1b0772ecce2ac1d77452efa7fb894eea83f95ef65154efc2a73eefc8bc0298c91cb609d1b587507decaae20e3411c3a6')
+
+prepare() {
+  cd "oolite-source-$pkgver"
+
+  # workaround for missing textures and fonts
+  rm deps/Linux-deps/include/png.h
+  rm deps/Linux-deps/include/pngconf.h
+}
+
+build() {
+  cd "oolite-source-$pkgver"
+  source /usr/share/GNUstep/Makefiles/GNUstep.sh
+  make -f Makefile release
+}
+
+package() {
+  cd "oolite-source-$pkgver"
+
+  mkdir -p ${pkgdir}/usr/games
+  mkdir -p ${pkgdir}/usr/share/{games/oolite,applications,pixmaps,doc/oolite}
+
+  cp -r oolite.app/* ${pkgdir}/usr/share/games/oolite/
+
+  install -Dm755 ${srcdir}/oolite ${pkgdir}/usr/games/oolite
+  install -Dm644 installers/FreeDesktop/oolite-icon.png ${pkgdir}/usr/share/pixmaps/oolite-icon.png
+  install -Dm644 installers/FreeDesktop/oolite.desktop ${pkgdir}/usr/share/applications/oolite.desktop
+  install -Dm644 Doc/AdviceForNewCommanders.pdf Doc/OoliteReadMe.pdf Doc/OoliteRS.pdf ${pkgdir}/usr/share/doc/oolite/
+
+  install -Dm644 Doc/LICENSE.TXT -t "${pkgdir}/usr/share/licenses/$pkgname"
+}