initial import

mygui/PKGBUILD

@@ -0,0 +1,48 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=mygui
+pkgver=3.4.1
+pkgrel=1
+pkgdesc="A multilayer and overlappable GUI System"
+arch=('i686' 'x86_64')
+url='http://mygui.info/'
+license=('Expat')
+depends=('sdl2' 'sdl2_image' 'glu')
+makedepends=('cmake' 'doxygen' 'graphviz' 'ttf-dejavu')
+install=$pkgname.install
+source=("https://github.com/MyGUI/mygui/archive/MyGUI${pkgver}.tar.gz")
+sha512sums=('9d36272345b1a755db88848c8a0919feb6f8ae09d048efa3b8ed833bb5ddb9c65e1e7e0d26ad39eecd2a4de53fb654f4099c555e9ebd21ce9541a1a74580ef05')
+
+build() {
+  cd mygui-MyGUI${pkgver}
+
+  # change CMake config so demos install to /opt
+  sed -i 's:"bin:"../opt/MYGUI:' ./CMake/Utils/MyGUIConfigTargets.cmake
+  sed -i -e 's:../share:/usr/share:' \
+         -e 's:"bin":"../opt/MYGUI":' \
+         ./CMake/InstallResources.cmake
+
+  # generate CMake Makefile
+  cmake -B build \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DMYGUI_INSTALL_TOOLS=TRUE \
+    -DMYGUI_INSTALL_DOCS=TRUE \
+    -DMYGUI_INSTALL_MEDIA=TRUE \
+    -DMYGUI_BUILD_DEMOS=TRUE \
+    -DMYGUI_BUILD_TOOLS=TRUE \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DMYGUI_RENDERSYSTEM=7 \
+    -DBUILD_SHARED_LIBS=TRUE
+
+  make -C build
+  make -C build api-docs
+}
+
+package() {
+  cd mygui-MyGUI${pkgver}
+
+  make -C build DESTDIR="$pkgdir" install
+
+  # install license
+  install -Dm644 COPYING.MIT -t "$pkgdir"/usr/share/licenses/$pkgname
+}

mygui/mygui.install

@@ -0,0 +1,3 @@
+post_install() {
+    echo "To view the MyGUI samples, go to /opt/MYGUI/ and run the samples individually"
+}