initial import

mesa-demos/PKGBUILD

@@ -0,0 +1,49 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname='mesa-demos'
+pkgver=8.4.0
+pkgrel=1
+arch=('i686' 'x86_64')
+pkgdesc="Mesa demos and tools incl. glxinfo + glxgears"
+url="https://www.mesa3d.org/"
+license=('Expat')
+depends=('mesa-libgl' 'glew' 'freeglut')
+mksource=("https://mesa.freedesktop.org/archive/demos/mesa-demos-${pkgver}.tar.bz2"{,.sig})
+source=("https://repo.hyperbola.info:50000/sources/mesa-demos-libre/mesa-demos-libre-${pkgver}.tar.lz"{,.sig}
+        'LICENSE'
+        'libre.patch')
+mksha512sums=('b72d03cad36e0535ff18dcfb222ec4200064b9264f6da51a6e5f03b0dd912abe188bc1d600b6698de3ce6f63b28d2ce01565886ca8e7079edc4967fbf2fb0957'
+              'SKIP')
+sha512sums=('51cd024ccc289ff135508af1a94b41f2eb5f696401a52ee6a5f759e078af2324ea4958a41672612cf1fd5adfa1713d74885bb029a0d943f0e4be5c0edcf99403'
+            'SKIP'
+            '25da77914dded10c1f432ebcbf29941124138824ceecaf1367b3deedafaecabc082d463abcfa3d15abff59f177491472b505bcb5ba0c4a51bb6b93b4721a23c2'
+            '22adbecafe2a822357bf1b266ba090d97ca5d0e80698aa0650df66a0026861ff3ba5404a7345e4cf5e5ff1e308774e363bff5248cb177548ee098a5347b6c92c')
+validpgpkeys=('E390B9700582FAEA959ACAD41EEF53D38A3A9C67'  # Andreas Boll
+              'C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva
+
+mksource() {
+  cd mesa-demos-$pkgver
+
+  # remove nonfree demos (dinoshade, pointblast and spriteblast)
+  rm -v src/demos/{dinoshade,pointblast,spriteblast}.c
+}
+
+prepare() {
+  cd mesa-demos-$pkgver
+
+  # remove nonfree demos references (pointblast and spriteblast)
+  patch -Np1 -i ../libre.patch
+}
+
+build() {
+  cd mesa-demos-$pkgver
+  ./configure --prefix=/usr \
+    --with-system-data-files=/usr/share/mesa-demos
+  make
+}
+
+package() {
+  cd mesa-demos-$pkgver
+  make DESTDIR="${pkgdir}" install
+  install -Dm644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/mesa-demos/LICENSE"
+}