initial import

mercurial/PKGBUILD

@@ -0,0 +1,59 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=mercurial
+pkgver=5.6.1
+pkgrel=1
+pkgdesc="A scalable distributed SCM tool"
+arch=('i686' 'x86_64')
+url='https://www.mercurial-scm.org/'
+license=('GPL-2')
+depends=('python')
+makedepends=('python-docutils')
+optdepends=('tk: for the hgk GUI')
+backup=(etc/mercurial/hgrc)
+validpgpkeys=(2BCCE14F5C6725AA2EA8AEB7B9C9DC824AA5BDD5
+              3A8155163D0E20A530FCB78647A67FFAA346AACE
+              EB851395B4223EE2F7BA0B28DA54740BF08732BA) # Pulkit Goyal <7895pulkit@gmail.com>
+source=(https://www.mercurial-scm.org/release/${pkgname}-${pkgver}.tar.gz{,.asc}
+        mercurial.profile)
+sha512sums=('d84d7d9ae4c738e3cb62b26c4dc7f3943abc1b1a55ccc46a4e3435896f715efb30d4d6ff4df6d02a8bef7bd6ead2d21a44342fb8a2101e8fe04211d21efc13b1'
+            'SKIP'
+            '710dcddb24d928efc97370e869d9caa083107929ed9a1086dd2a3ae0caaf2c71e2f29060597e29315b6b15b1616251c42412e268ce737109c48ae4d7aa1b9555')
+
+build() {
+  cd $pkgname-$pkgver
+  make
+  make -C contrib/chg
+}
+
+package() {
+  cd $pkgname-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  make DESTDIR="${pkgdir}" PREFIX=/usr install
+
+  install -m644 -D contrib/zsh_completion "$pkgdir/usr/share/zsh/site-functions/_hg"
+  install -m644 -D contrib/bash_completion "$pkgdir/usr/share/bash-completion/completions/hg"
+
+  make -C contrib/chg DESTDIR="$pkgdir" PREFIX=/usr install
+  install -m755 contrib/hg-ssh "$pkgdir/usr/bin"
+  install -m755 contrib/hgk "$pkgdir/usr/bin"
+
+  install -d "$pkgdir/usr/share/emacs/site-lisp"
+  install -m644 contrib/{mq.el,mercurial.el} "$pkgdir/usr/share/emacs/site-lisp"
+
+  install -Dm644 contrib/vim/HGAnnotate.vim \
+    "$pkgdir/usr/share/vim/vimfiles/syntax/HGAnnotate.vim"
+
+  # set some variables
+  install -m755 -d "$pkgdir/etc/profile.d"
+  install -m755 "$srcdir/mercurial.profile" "$pkgdir/etc/profile.d/mercurial.sh"
+
+  # add certs config to package
+  install -m755 -d "$pkgdir/etc/mercurial"
+  cat <<-EOF > "$pkgdir/etc/mercurial/hgrc"
+	[web]
+	cacerts = /etc/ssl/certs/ca-certificates.crt
+	EOF
+
+  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
+}

mercurial/mercurial.profile

@@ -0,0 +1 @@
+export HG=/usr/bin/hg