initial import

meandmyshadow/PKGBUILD

@@ -0,0 +1,34 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=meandmyshadow
+pkgver=0.5a
+pkgrel=1
+pkgdesc="Free and libre puzzle / platform game in which you try to reach the exit by solving tasks"
+arch=('i686' 'x86_64')
+url='https://meandmyshadow.sourceforge.net/'
+license=('GPL-3')
+depends=('sdl2_gfx' 'sdl2_image' 'sdl2_ttf' 'sdl2_mixer' 'curl' 'libarchive' 'hicolor-icon-theme' 'mesa-libgl' 'lua')
+makedepends=('cmake' 'gettext-tiny')
+groups=('games')
+source=("https://sourceforge.net/projects/${pkgname}/files/${pkgver}/${pkgname}-${pkgver}-src.tar.gz")
+sha512sums=('c9e6de9c9b47af3839b6830faa3619ddc69b2c2cabf4d90f4c1393758805acf9835abcba45d79037766b4b6e5f006e6f880eba593d1142b0e829a887eb844f27')
+
+build() {
+  cmake \
+    -S "$pkgname-$pkgver" \
+    -B build \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DBINDIR=games \
+    -DDATAROOTDIR=/usr/share/games
+  make -C build
+}
+
+package() {
+  make DESTDIR="${pkgdir}" -C build install
+
+  # correct package-structure
+  mv "$pkgdir/usr/share/games/"{applications,icons} "$pkgdir/usr/share/"
+
+  install -Dm644 "$srcdir/$pkgname-$pkgver/COPYING" -t "$pkgdir/usr/share/licenses/$pkgname"
+}