initial import

md4c/PKGBUILD

@@ -0,0 +1,47 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=md4c
+pkgver=0.4.7
+_debver=0.4.7
+_debrel=1
+pkgrel=1
+pkgdesc="C Markdown parser"
+arch=(i686 x86_64)
+url="https://github.com/mity/md4c"
+license=(Expat)
+depends=(glibc)
+makedepends=(cmake quilt)
+source=($pkgname-$pkgver.tar.gz::"https://github.com/mity/md4c/archive/release-$pkgver.tar.gz"
+        https://deb.debian.org/debian/pool/main/m/md4c/md4c_$_debver-$_debrel.debian.tar.xz)
+sha512sums=('90e6f4c91ff5a0faafcea3e50f6a3f3ed6ba9a42cb779b373e82b8a6a09ed4b19ed7221036a4a32171aa5ef19ee6824d3830fb9ab613bd59174b7db51bd1099b'
+            '2a1515dda2cedab2c3b34998728607a635a048b8ebc4db852e4d8be42b752a926fe3125e3931c4b256290dc52c6d154ebd725d7138e70f7665fb27db23764a3c')
+
+prepare() {
+  mkdir -p build
+
+  cd $pkgname-release-$pkgver
+  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
+    # Debian patches
+    export QUILT_PATCHES=debian/patches
+    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
+    export QUILT_DIFF_ARGS='--no-timestamps'
+
+    mv "$srcdir"/debian .
+
+    quilt push -av
+  fi
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-release-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+
+  install -Dm644 "$srcdir"/$pkgname-release-$pkgver/LICENSE.md -t "$pkgdir"/usr/share/licenses/$pkgname/
+}