initial import

lite/PKGBUILD

@@ -0,0 +1,34 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=lite
+pkgver=1.11
+pkgrel=2
+pkgdesc="A lightweight text editor written in Lua"
+arch=('i686' 'x86_64')
+url='https://github.com/rxi/lite'
+license=('Expat')
+depends=('sdl2')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/rxi/lite/archive/v$pkgver.tar.gz"
+        "$pkgname-path-fix.patch")
+sha512sums=('2fe3a651cc3ddedd67d8b8f2b53b262eed8a64295d65d31b17ff80f787cfe53fd82c8e69aaaada7806c08f9814eb4a576668dc5614de43ddf2caa6d5aae338f0'
+            '6db0ea772befa653a962e6d28311b3485f983e6dcbb29514a771222fc2d68d282306571b1afe3284881a85ffd77e7d31323d0c5c3631c0bdea8aa6220d90cc40')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  patch -p1 < "$srcdir/$pkgname-path-fix.patch"
+  sed -i -e '/^cflags=/s/"/"$CFLAGS /' \
+         -e '/^lflags=/s/"/"$LDFLAGS /' build.sh
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  ./build.sh
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  install -Dm755 -t "$pkgdir/usr/bin/" $pkgname
+  install -d "$pkgdir/usr/share/$pkgname"
+  cp -a data/* "$pkgdir/usr/share/$pkgname/"
+  install -Dm644 LICENSE -t $pkgdir/usr/share/licenses/$pkgname
+}