initial import

libstrophe/PKGBUILD

@@ -0,0 +1,34 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=libstrophe
+pkgver=0.12.3
+pkgrel=1
+pkgdesc="Simple, lightweight C library for writing XMPP clients"
+url='https://strophe.im/libstrophe/'
+arch=('i686' 'x86_64')
+license=('GPL-3' 'Expat')
+depends=('glibc' 'libressl' 'expat')
+makedepends=('doxygen')
+source=("https://github.com/strophe/libstrophe/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('da4597faa3d277d4cf557e07a10d8974239de38a0396a545f98ea5f8c39c1e00b0de9cde56a2a438115ad07c98658859c8b623273f083ce1f642a000ecc4efde')
+
+prepare() {
+  cd ${pkgbase}-${pkgver}
+  autoreconf -fiv
+}
+
+build() {
+  cd ${pkgbase}-${pkgver}
+  ./configure \
+    --prefix=/usr
+  make
+  doxygen
+}
+
+package() {
+  cd ${pkgbase}-${pkgver}
+  make DESTDIR="${pkgdir}" install
+  install -Dm 644 docs/html/* -t "${pkgdir}/usr/share/doc/${pkgname}/html"
+  install -Dm 644 examples/{README.md,*.c} -t "${pkgdir}/usr/share/doc/${pkgname}/examples"
+  install -Dm 644 {MIT,GPL}-LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}