initial import

librsvg-legacy/PKGBUILD

@@ -0,0 +1,55 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+# Based on librsvg package
+
+_pkgname=librsvg
+pkgname=librsvg-legacy
+pkgver=2.40.21
+_debver=$pkgver
+_debrel=0
+pkgrel=3
+pkgdesc="SVG rendering library"
+url='https://wiki.gnome.org/Projects/LibRsvg'
+arch=(i686 x86_64)
+license=(LGPL-2)
+replaces=(librsvg)
+conflicts=(librsvg)
+provides=(librsvg)
+depends=(gdk-pixbuf2 pango libcroco)
+makedepends=(intltool gobject-introspection vala tauthon quilt)
+source=(https://download.gnome.org/sources/$_pkgname/${pkgver:0:4}/$_pkgname-$pkgver.tar.xz
+        https://snapshot.debian.org/archive/debian-security/20200722T102253Z/pool/updates/main/libr/librsvg/librsvg_${_debver}-${_debrel}+deb9u1.debian.tar.xz)
+sha512sums=('db0563d8e0edaae642a6b2bcd239cf54191495058ac8c7ff614ebaf88c0e30bd58dbcd41f58d82a9d5ed200ced45fc5bae22f2ed3cf3826e9348a497009e1280'
+            'f3c8c1f889c7a930e8858ed87b30dac4faaa94c5ffd55bb65f3f88768ad20a80348b8b5617e433b9a12235a27a8bad7886dd9528cfca8e980e54bffad3ba5572')
+
+prepare() {
+  cd $_pkgname-$pkgver
+
+  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
+    # Debian patches
+    export QUILT_PATCHES=debian/patches
+    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
+    export QUILT_DIFF_ARGS='--no-timestamps'
+
+    mv "$srcdir"/debian .
+
+    quilt push -av
+  fi
+}
+
+build() {
+  cd $_pkgname-$pkgver
+  ./configure --prefix=/usr --disable-static --enable-vala --disable-gtk-doc
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' libtool
+  make
+}
+
+package() {
+  cd $_pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+
+  # we don't support gtk-doc
+  rm -rf $pkgdir/usr/share/gtk-doc
+
+  install -Dm644 COPYING.LIB $pkgdir/usr/share/licenses/$pkgname/COPYING.LIB
+}