initial import

libmp3splt/PKGBUILD

@@ -0,0 +1,34 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=libmp3splt
+pkgver=0.9.2
+pkgrel=1
+pkgdesc="Library for splitting mp3 and ogg files without decoding"
+arch=('i686' 'x86_64')
+url='http://mp3splt.sourceforge.net'
+license=('GPL-2')
+depends=('flac' 'libmad' 'libvorbis' 'libid3tag' 'pcre' 'libtool')
+makedepends=('libtool')
+source=("https://downloads.sourceforge.net/sourceforge/mp3splt/$pkgname-$pkgver.tar.gz"
+        "properly-zero-initialise-the-ogg-and-vorbis-state.patch")
+sha512sums=('e5c98e8b173bc86302ccee4ca5eb0c8a8d93f225357eb7b14dea8d0700ed62ed6316506c182f6b295130f7924ff0b38e865d5e49fa9cd7882c648360d68872ed'
+            'ec9904f86fb631520b4c06c03dcd7fde2b17a0ebdf7e77f36c47bddcaa49961f639c91976470bcd571001d133b724403eb4ffe550c14b49ae883940d914567e9')
+
+prepare() {
+  cd $pkgname-$pkgver
+  patch -Np1 -i ${srcdir}/properly-zero-initialise-the-ogg-and-vorbis-state.patch
+  libtoolize --copy --force
+  ./autogen.sh
+}
+
+build() {
+   cd $pkgname-$pkgver
+  ./configure --prefix=/usr
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir/" install
+  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
+}