initial import

libjpeg-turbo/PKGBUILD

@@ -0,0 +1,74 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=libjpeg-turbo
+pkgver=2.0.5
+_debver=2.0.5
+_debrel=2
+pkgrel=2
+pkgdesc='JPEG image codec with accelerated baseline compression and decompression'
+url='https://libjpeg-turbo.org/'
+arch=('i686' 'x86_64')
+license=('custom:IJG' 'Modified-BSD' 'zlib')
+makedepends=('cmake' 'nasm' 'quilt')
+validpgpkeys=('7D6293CC6378786E1B5C496885C7044E033FDE16')
+source=("https://downloads.sourceforge.net/project/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz"
+        "https://deb.debian.org/debian/pool/main/libj/libjpeg-turbo/libjpeg-turbo_$_debver-$_debrel.debian.tar.xz"
+        'COPYING.BSD3'
+        'COPYING.IJG'
+        'COPYING.ZLIB')
+sha512sums=('5bf9ecf069b43783ff24365febf36dda69ccb92d6397efec6069b2b4f359bfd7b87934a6ce4311873220fccc73acabdacef5ce0604b79209eb1912e8ba478555'
+            'ca6ee52c3fa944e56139054249aaedae7615f7f619f4ba39ae3c57fcac111466de4f7da0db8e6d9b4073cb07b9d32a3941fcdba5098031e4882e8a55e6bad1e6'
+            '99bf74a259f531b79309ce5e02ced1beceebb0a7269231ee2ea7f496b4584670dbb72c06cb60f7b8f84db1212a14b7b818beb3cac3b5e503aa2852c6166e9a74'
+            '77a09897f1f637a3ff3acfffb2bbdda0e446bd8b1307f1b4dc3a40566247123b39fe4755318380cf38d5afc8724055f4f27496340b6f4a1e2931299e2259d4fb'
+            '3bdfc937b59fd314f57f32d9943f332a2196d29935967dc5677e2eb81355511027d9411bf8937369732ca3adccf54bb91d563de295e841e896758d4441516586')
+
+provides=('libjpeg=8.2.2' 'turbojpeg')
+conflicts=('libjpeg' 'turbojpeg')
+replaces=('libjpeg' 'turbojpeg')
+
+prepare() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
+		# Debian patches
+		export QUILT_PATCHES=debian/patches
+		export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
+		export QUILT_DIFF_ARGS='--no-timestamps'
+
+		mv "$srcdir"/debian .
+
+		quilt push -av
+	fi
+}
+
+build() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+
+	cmake \
+		-DWITH_JAVA=0 \
+		-DWITH_JPEG8=1 \
+		-DCMAKE_INSTALL_PREFIX=/usr \
+		-DCMAKE_INSTALL_LIBDIR=/usr/lib \
+		.
+
+	make
+}
+
+check() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	make test
+}
+
+package() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	make \
+		DESTDIR="${pkgdir}" \
+		docdir="/usr/share/doc/${pkgname}" \
+		exampledir="/usr/share/doc/${pkgname}" \
+		install
+
+	install -Dm644 LICENSE.md "${pkgdir}/usr/share/licenses/libjpeg-turbo/LICENSE.md"
+	for i in COPYING.{BSD3,IJG,ZLIB}; do
+		install -Dm644 "${srcdir}/${i}" "${pkgdir}/usr/share/licenses/libjpeg-turbo/${i}"
+	done
+	install -m644 jpegint.h "${pkgdir}/usr/include" # required by other software
+}