initial import

krita-legacy/PKGBUILD

@@ -0,0 +1,44 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+_realpkgname=krita
+pkgname=$_realpkgname-legacy
+pkgver=4.4.2
+pkgrel=1
+pkgdesc="Raster graphics editor and 2D animations (legacy version)"
+arch=('i686' 'x86_64')
+url='https://krita.org'
+license=('GPL-3')
+depends=('boost-libs' 'desktop-file-utils' 'eigen' 'exiv2' 'fftw' 'giflib' 'gsl' 'hicolor-icon-theme'
+         'kcompletion' 'kcrash' 'kseexpr' 'kguiaddons' 'kitemmodels' 'kitemviews' 'libraw'
+         'poppler-qt' 'python-pyqt' 'qt-multimedia' 'qt-svg' 'quazip')
+makedepends=('boost' 'extra-cmake-modules' 'gettext-tiny' 'python-setuptools' 'sip' 'vc')
+optdepends=('ffmpeg: to save animations'
+            'qt-imageformats: to support some image formats')
+source=("https://download.kde.org/Attic/${_realpkgname}/${pkgver}/${_realpkgname}-${pkgver}.tar.gz")
+sha512sums=('62fe7d719d119099a10277e03b2cf48cefebe30daa664867dad989b812e58959abf34169b06aa5b8e9430aa92378b847f42ecfc38e0f8f20b3d8060f983eaac2')
+
+build() {
+  cmake -B build -S $_realpkgname-$pkgver \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_TESTING=OFF \
+    -Wno-dev
+  make -C build
+}
+
+package() {
+  make DESTDIR="$pkgdir" -C build install
+
+  # Hotfix Krita 4.X in Qt5-Base 5.15.X QPalette::QPalette C++ Method error.
+  # https://sourceforge.net/p/qt5ct/tickets/77/
+  install -dm 755 $pkgdir/usr/libexec
+  mv $pkgdir/usr/bin/$_realpkgname $pkgdir/usr/libexec
+  printf '%s\n%s %s\n' \
+    '#!/bin/sh' \
+    'QT_QPA_PLATFORMTHEME=qt5ct' \
+    "/usr/libexec/$_realpkgname" \
+    > $pkgdir/usr/bin/$_realpkgname
+  chmod 0755 $pkgdir/usr/bin/$_realpkgname
+
+  install -Dm644 $_realpkgname-$pkgver/COPYING -t $pkgdir/usr/share/licenses/$pkgname
+}