initial import

jwm/PKGBUILD

@@ -0,0 +1,43 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=jwm
+pkgver=2.4.6
+pkgrel=1
+pkgdesc="A lightweight window manager for the X11 Window System"
+arch=('i686' 'x86_64')
+url='https://joewing.net/projects/jwm/'
+license=('Expat')
+depends=('libx11' 'libxft' 'libxmu' 'libjpeg-turbo' 'libxpm' 'libxinerama' 'libpng' 'cairo' 'librsvg-legacy')
+makedepends=('gettext-tiny')
+backup=('etc/system.jwmrc')
+source=("https://github.com/joewing/jwm/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.xz"
+        "$pkgname.desktop")
+sha512sums=('daf1bf033f2055534bab7ac5a12966df69039d3af2a220d1c9ce2126759019c9e6fea1a50fdf72d30be36d0cd22f243d11010d50f4b0795577b4d74209b82bd6'
+            '1e033d4edfca67c7de47e92404dc718e4ab2fc716b4f9f4bb21ddca525dcee7828b585f84695e02c176391ed0dcb1c8251772f4a946d0c3d06c4b190347c2cc4')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+
+  # fixing example-configuration
+  sed -i 's|/usr/local/share/|/usr/share/|' contrib/Makefile po/Makefile* example.jwmrc
+
+  # remove non-free applications
+  sed -i -e 's|Firefox|Iceweasel-UXP|g' -e 's|firefox|iceweasel-uxp|g' example.jwmrc
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc
+
+  make
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  make BINDIR="$pkgdir/usr/bin" MANDIR="$pkgdir/usr/share/man" DESTDIR="$pkgdir" SYSCONF="$pkgdir/etc" install
+  install -Dm644 $srcdir/$pkgname.desktop -t "$pkgdir/usr/share/xsessions"
+  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+}