initial import

irrlamb/PKGBUILD

@@ -0,0 +1,36 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=irrlamb
+pkgver=1.0.7
+pkgbuild=d99c154
+pkgrel=1
+pkgdesc="Free and libre 3D game that probably involves a lot of physics and frustrating gameplay"
+arch=('i686' 'x86_64')
+url='https://irrlamb.gitlab.io/'
+license=('GPL-3')
+depends=('gcc-libs' 'freetype2' 'sqlite' 'openal' 'libvorbis' 'libogg'
+         'libjpeg-turbo' 'libpng' 'zlib' 'libx11' 'libxrandr' 'mesa-libgl')
+makedepends=('cmake')
+groups=('games')
+source=("${pkgname}-${pkgver}.tar.gz::https://gitlab.com/jazztickets/uploads/-/raw/main/${pkgname}-${pkgver}-${pkgbuild}-src.tar.gz")
+sha512sums=('eca084e6e3486b22df6bc3500d2d22b81043477d89e91c1f225c0c4adab3d973d2b2af9ac792e2d53ef370ef0f34e4101f31550f248288f14840e3593ce35ea4')
+
+build() {
+  cmake \
+    -S ${pkgname}-${pkgver}-${pkgbuild} \
+    -B build \
+    -DCMAKE_INSTALL_PREFIX=/usr
+  make -C build
+}
+
+package() {
+  make DESTDIR="$pkgdir/" -C build install
+
+  # move binary to correct location for being FHS-compliant
+  install -d -m755 "${pkgdir}/usr/games"
+  mv "${pkgdir}/usr/bin/irrlamb" "${pkgdir}/usr/games"
+  rm -rf "${pkgdir}/usr/bin"
+
+  # license
+  install -Dm644 "${srcdir}/${pkgname}-${pkgver}-${pkgbuild}/LICENSE" -t "${pkgdir}/usr/share/licenses/$pkgname"
+}