initial import

icewm/PKGBUILD

@@ -0,0 +1,46 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=icewm
+pkgver=3.6.0
+pkgrel=2
+pkgdesc="Free and libre window manager designed for speed, usability and consistency"
+arch=('i686' 'x86_64')
+url='https://ice-wm.org/'
+license=('GPL-2')
+depends=('imlib2' 'librsvg-legacy' 'libsndfile' 'libxcomposite' 'libxdamage' 'libxinerama' 'libxpm' 'libxrandr' 'libao')
+makedepends=('asciidoctor' 'xenocara-mkfontscale' 'gettext-tiny')
+optdepends=('perl: for icewm-menu-xrandr')
+source=("https://github.com/ice-wm/icewm/releases/download/$pkgver/${pkgname}-${pkgver}.tar.lz"
+        "libre.patch")
+sha512sums=('510c342ab98fe248bfaf4e925a92059ffc7e23e6f47725c274970e1ab751ce57405e52ac5de0e05a1dfa65260c64a4db3c87f8b560e27528aea88ba45cd83920'
+            '93e0dab410c6d3b61fe7e9e94861d2bd3842be4d8499fc9b1b7366cafee7023375838b60d052031fa6c3b110fa426fb5fb43b8456ac8b761f35782f40eba3d02')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+
+  # remove non-free parts
+  rm -rf ./lib/themes/NanoBlue
+  rm ./lib/icons/{communicator-abook,communicator-browser,communicator-composer,communicator-discussion,communicator-mail,emacs,gnome,java,kde,navigator,netscape,pdf}_16x16.xpm
+  rm ./lib/icons/{communicator-abook,communicator-browser,communicator-composer,communicator-discussion,communicator-mail,emacs,java,navigator,netscape,pdf}_32x32.xpm
+  rm ./lib/taskbar/debian.xpm
+  patch -Np1 -i ${srcdir}/libre.patch
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --with-icesound=AO
+  make
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  make DESTDIR="$pkgdir" install
+
+  # remove unwanted data
+  rm "${pkgdir}/usr/bin/icewm-set-gnomewm"
+
+  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
+}