initial import

grip/PKGBUILD

@@ -0,0 +1,43 @@
+# Maintainer: Jesus E. <heckyel@riseup.net>
+
+pkgname=grip
+pkgver=4.2.4
+pkgrel=1
+pkgdesc="A free and libre CD-player and CD-ripper"
+arch=('i686' 'x86_64')
+license=('GPL-2')
+url='https://sourceforge.net/projects/grip/'
+depends=('curl' 'id3lib' 'cdparanoia' 'gtk2')
+makedepends=('pkgconfig')
+optdepends=('yelp: to display the help and notices'
+            'lame: for mp3 support'
+            'vorbis-tools: for ogg support'
+            'flac: for flac support')
+source=("https://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.gz"
+        "remove-cddb.patch")
+sha512sums=('fdc2808b91df617f4d2447114037c31bd5fa0657aa4ea2453e644b155468971c65a364bb0a3c6ed8ff2ba0e44e7117a51bec3081c7defd590f9fbc802a216bf5'
+            'fcd30a74d145bb065c193d84bbd8613be1e6d6c8b255105d7458ded0fd4fd260090850b9db9d7abfb05c8e477ff30d6c75074844b5612aedb69339adcb31189d')
+
+prepare() {
+  cd ${pkgname}-${pkgver}
+  patch -Np1 -i ${srcdir}/remove-cddb.patch
+}
+
+build() {
+  cd ${pkgname}-${pkgver}
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var
+  make
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make DESTDIR="${pkgdir}" install
+
+  # remove unneeded data
+  rm -rf "$pkgdir/usr/share/solid"
+
+  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
+}